dev-libs/feedbackd: add daemon USE flag

Signed-off-by: Julien Roy <julien@jroy.ca>

dev-libs/feedbackd/Manifest

@@ -1,2 +1,3 @@
 DIST feedbackd-v0.0.3.tar.gz 92301 BLAKE2B 53849f68106423db287a7961140f37141e4911e538a67e8e45afdbe9d69861089d9ac64f002de12794fbe00bfc09bbcb9fc5909a6c961df6d0f6cc8c3ff875c9 SHA512 de4365b8941e93a81618e4f2a3f5575d28f81ac53dcb54c249c5e3494157091e06fc55a522e76933304303d6b5ecba9697c5639a2838441637468f21502f4d92
 DIST feedbackd-v0.1.0.tar.bz2 75888 BLAKE2B a33d5161a1e83696a0d21a4487070abc7b31a1634cd6ca715bf489a29bf3e5c4f72b3838b87cde1e361df063ea829ca40083592681d46db2a324a7db1995dffb SHA512 e056dc3441318237f7faae7ceefbbcbc5a3078a622fad8a35265074c15d3236fc90932d38c32acb4ac1dcbefadc0548aec135caff7918d2979b1b5b1b6821aeb
+DIST gmobile-d483537aee4778b114ce5d50c4c8a9f8d58337ed.tar.bz2 20337 BLAKE2B f94295672ed699f308ccfab3835ed6c7f1184c0e267ea1c2ab7b6d59c98b3d027b300bf6d29db6442de20cec852f5c1031d1b09f220e94afc79c48566c160676 SHA512 86acabbffb1b5f98f2b132ce5bd12940769c11ed53d38401a0048216943a4b095bd230774d83444e7b5f5d26825f32ced0075dce7354f6fa486d47ef5f86b4f3

dev-libs/feedbackd/feedbackd-0.1.0-r1.ebuild

@@ -0,0 +1,70 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+VALA_USE_DEPEND="vapigen"
+
+inherit vala meson
+
+GMOBILECOMMIT="d483537aee4778b114ce5d50c4c8a9f8d58337ed"
+DESCRIPTION="A daemon to provide haptic feedback on events"
+HOMEPAGE="https://source.puri.sm/Librem5/feedbackd"
+SRC_URI="https://source.puri.sm/Librem5/${PN}/-/archive/v${PV}/${PN}-v${PV}.tar.bz2
+	https://gitlab.gnome.org/guidog/gmobile/-/archive/${GMOBILECOMMIT}.tar.bz2
+	-> gmobile-${GMOBILECOMMIT}.tar.bz2
+"
+S="${WORKDIR}/${PN}-v${PV}"
+
+LICENSE="LGPL-3"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+SLOT="0"
+IUSE="daemon gtk-doc +introspection man test +vala"
+REQUIRED_USE="vala? ( introspection )"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	dev-libs/glib:2
+	introspection? ( dev-libs/gobject-introspection )
+"
+RDEPEND="${DEPEND}
+	dev-libs/feedbackd-device-themes
+"
+BDEPEND="
+	dev-util/gdbus-codegen
+	gtk-doc? ( dev-util/gi-docgen )
+	man? ( dev-python/docutils )
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	default
+
+	if use daemon; then
+		rmdir "${S}/subprojects/gmobile" || die
+		mv "${WORKDIR}/gmobile-${GMOBILECOMMIT}" "${S}/subprojects/gmobile" || die
+	fi
+
+	use vala && vala_setup
+	sed -i 's/-G feedbackd/-G video/g' debian/feedbackd.udev || die
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature introspection)
+		$(meson_use daemon)
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use man)
+		$(meson_use test tests)
+		$(meson_use vala vapi)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	if use gtk-doc; then
+		mkdir -p "${ED}"/usr/share/gtk-doc/html/ || die
+		mv "${ED}"/usr/share/doc/libfeedback-${SLOT} "${ED}"/usr/share/gtk-doc/html/ || die
+	fi
+}

dev-libs/feedbackd/metadata.xml

@@ -9,4 +9,7 @@
 		<email>gjdijkman@gjdwebserver.nl</email>
 		<name>Gerben Jan Dijkman</name>
 	</maintainer>
+	<use>
+		<flag name="daemon">Build the feedbackd daemon</flag>
+	</use>
 </pkgmetadata>