dev-cpp/highway: version bump to 0.15.0

Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Daniel Novomesky <dnovomesky@gmail.com>

dev-cpp/highway/highway-0.15.0.ebuild

@@ -0,0 +1,42 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="Performance-portable, length-agnostic SIMD with runtime dispatch"
+HOMEPAGE="https://github.com/google/highway"
+
+if [[ "${PV}" == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/google/highway.git"
+else
+	SRC_URI="https://github.com/google/highway/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="test"
+
+DEPEND="test? ( dev-cpp/gtest )"
+
+PATCHES=( "${FILESDIR}/${PN}-shared-libraries.patch" )
+RESTRICT="!test? ( test )"
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_TESTING=$(usex test)
+		-DHWY_WARNINGS_ARE_ERRORS=OFF
+	)
+
+	use test && mycmakeargs+=( "-DHWY_SYSTEM_GTEST=ON" )
+
+	cmake_src_configure
+}
+
+src_install() {
+	dodoc g3doc/*
+	cmake_src_install
+}