diff --git a/dev-python/chalice/Manifest b/dev-python/chalice/Manifest
new file mode 100644
index 0000000000..d5303b0c5d
--- /dev/null
+++ b/dev-python/chalice/Manifest
@@ -0,0 +1 @@
+DIST chalice-1.32.0.gh.tar.gz 2763823 BLAKE2B ced70b1a21398abdc7381ae0d1db818f0eca532bfa046c56c9a88ce4e91271b0124340af839a826730a9fa47c17108af0049a0227d853261204d333a5c367b94 SHA512 edddb135df4177f9dc9d36dee9ac61dbff52ef10ddb95469741e196a344a3fd4569ec2f785121b6c4aa8988bdd44971f8fa0c23e64a5f86447006ad74bc0d5d7
diff --git a/dev-python/chalice/chalice-1.32.0.ebuild b/dev-python/chalice/chalice-1.32.0.ebuild
new file mode 100644
index 0000000000..a78bbdb290
--- /dev/null
+++ b/dev-python/chalice/chalice-1.32.0.ebuild
@@ -0,0 +1,84 @@
+# Copyright 2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+# py3.14: https://github.com/aws/chalice/issues/2150
+PYTHON_COMPAT=( python3_{12..13} )
+
+inherit distutils-r1 #pypi
+
+DESCRIPTION="Python Serverless Microframework for AWS"
+HOMEPAGE="
+	https://github.com/aws/chalice/
+	https://pypi.org/project/chalice/
+"
+# no tests in sdist
+SRC_URI="
+	https://github.com/aws/chalice/archive/refs/tags/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+
+# <dev-python/pip-25.1[${PYTHON_USEDEP}]: patched out
+RDEPEND="
+	<dev-python/click-9.0[${PYTHON_USEDEP}]
+	>=dev-python/click-7[${PYTHON_USEDEP}]
+	<dev-python/botocore-2.0.0[${PYTHON_USEDEP}]
+	>=dev-python/botocore-1.14.0[${PYTHON_USEDEP}]
+	<dev-python/six-2.0.0[${PYTHON_USEDEP}]
+	>=dev-python/six-1.10.0[${PYTHON_USEDEP}]
+	>=dev-python/pip-9[${PYTHON_USEDEP}]
+	<dev-python/jmespath-2.0.0[${PYTHON_USEDEP}]
+	>=dev-python/jmespath-0.9.3[${PYTHON_USEDEP}]
+	<dev-python/pyyaml-7.0.0[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-5.3.1[${PYTHON_USEDEP}]
+	<dev-python/inquirer-4.0.0[${PYTHON_USEDEP}]
+	>=dev-python/inquirer-3.0.0[${PYTHON_USEDEP}]
+	dev-python/wheel[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		<dev-python/boto3-2[${PYTHON_USEDEP}]
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+		<dev-python/websocket-client-2.0.0[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_DESELECT=(
+	# FIXME
+	"tests/functional/cli/test_factory.py::test_can_create_botocore_session_debug"
+	# looks to to be tricky
+	"tests/unit/deploy/test_packager.py::TestPipRunner::test_build_wheel"
+	# network-sandbox
+	"tests/functional/test_awsclient.py::TestUpdateDomainName::test_update_domain_name_failed"
+	"tests/functional/test_deployer.py::test_no_error_message_printed_on_empty_reqs_file"
+	# pinned deps checker
+	"tests/integration/test_package.py::TestPackage::test_can_package_with_dashes_in_name"
+	"tests/integration/test_package.py::TestPackage::test_can_package_simplejson"
+	"tests/integration/test_package.py::TestPackage::test_can_package_sqlalchemy"
+	"tests/integration/test_package.py::TestPackage::test_can_package_pandas"
+	"tests/integration/test_package.py::TestPackage::test_packaging_requirements_keeps_same_hash"
+)
+EPYTEST_PLUGINS=()
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+PATCHES=(
+	"${FILESDIR}"/chalice-1.32.0-botocore-unvendor.patch
+)
+
+python_prepare_all() {
+	sed -e '/install_requires/,/^\]$/ { /pip/ s/<25.1// }' -i setup.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	epytest tests/unit tests/functional tests/integration
+}
diff --git a/dev-python/chalice/files/chalice-1.32.0-botocore-unvendor.patch b/dev-python/chalice/files/chalice-1.32.0-botocore-unvendor.patch
new file mode 100644
index 0000000000..9605be6c22
--- /dev/null
+++ b/dev-python/chalice/files/chalice-1.32.0-botocore-unvendor.patch
@@ -0,0 +1,60 @@
+diff --git a/chalice/awsclient.py b/chalice/awsclient.py
+index ff28738..bc3fd31 100644
+--- a/chalice/awsclient.py
++++ b/chalice/awsclient.py
+@@ -44,10 +44,10 @@ import botocore.session  # noqa
+ from botocore.loaders import create_loader
+ from botocore.exceptions import ClientError
+ from botocore.utils import datetime2timestamp
+-from botocore.vendored.requests import (
++from requests import (
+     ConnectionError as RequestsConnectionError,
+ )
+-from botocore.vendored.requests.exceptions import (
++from requests.exceptions import (
+     ReadTimeout as RequestsReadTimeout,
+ )
+ from typing import TypedDict
+diff --git a/chalice/deploy/deployer.py b/chalice/deploy/deployer.py
+index de1c17c..4feba5f 100644
+--- a/chalice/deploy/deployer.py
++++ b/chalice/deploy/deployer.py
+@@ -88,7 +88,7 @@ import socket
+ import logging
+ 
+ import botocore.exceptions
+-from botocore.vendored.requests import ConnectionError as \
++from requests import ConnectionError as \
+     RequestsConnectionError
+ from botocore.session import Session  # noqa
+ from typing import Optional, Dict, List, Any, Type, cast  # noqa
+diff --git a/tests/functional/test_awsclient.py b/tests/functional/test_awsclient.py
+index c565dd7..03f805f 100644
+--- a/tests/functional/test_awsclient.py
++++ b/tests/functional/test_awsclient.py
+@@ -5,9 +5,9 @@ from unittest import mock
+ 
+ import pytest
+ import botocore.exceptions
+-from botocore.vendored.requests import ConnectionError as \
++from requests import ConnectionError as \
+     RequestsConnectionError
+-from botocore.vendored.requests.exceptions import ReadTimeout as \
++from requests.exceptions import ReadTimeout as \
+     RequestsReadTimeout
+ from botocore import stub
+ from botocore.utils import datetime2timestamp
+diff --git a/tests/unit/deploy/test_deployer.py b/tests/unit/deploy/test_deployer.py
+index 0fbe1b9..98bd2cd 100644
+--- a/tests/unit/deploy/test_deployer.py
++++ b/tests/unit/deploy/test_deployer.py
+@@ -8,7 +8,7 @@ import botocore.session
+ import pytest
+ from unittest import mock
+ from botocore.stub import Stubber
+-from botocore.vendored.requests import ConnectionError as \
++from requests import ConnectionError as \
+     RequestsConnectionError
+ from pytest import fixture
+ 
+
diff --git a/dev-python/chalice/metadata.xml b/dev-python/chalice/metadata.xml
new file mode 100644
index 0000000000..6c36764b3c
--- /dev/null
+++ b/dev-python/chalice/metadata.xml
@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>negril.nx+gentoo@gmail.com</email>
+		<name>Paul Zander</name>
+	</maintainer>
+	<stabilize-allarches/>
+	<upstream>
+		<remote-id type="github">aws/chalice</remote-id>
+		<remote-id type="pypi">chalice</remote-id>
+	</upstream>
+</pkgmetadata>