From c4d9b38c9d251f142f309197e6e648444e577172 Mon Sep 17 00:00:00 2001
From: David Roman <stkw0@disroot.org>
Date: Mon, 22 Jun 2026 11:29:59 +0200
Subject: [PATCH] dev-cpp/wt: add 4.13.3

Signed-off-by: David Roman <stkw0@disroot.org>
---
 dev-cpp/wt/Manifest         |   1 +
 dev-cpp/wt/wt-4.13.3.ebuild | 131 ++++++++++++++++++++++++++++++++++++
 2 files changed, 132 insertions(+)
 create mode 100644 dev-cpp/wt/wt-4.13.3.ebuild

diff --git a/dev-cpp/wt/Manifest b/dev-cpp/wt/Manifest
index c8b29c242b..cd4ed3155b 100644
--- a/dev-cpp/wt/Manifest
+++ b/dev-cpp/wt/Manifest
@@ -1,2 +1,3 @@
 DIST wt-4.12.6.tar.gz 10967306 BLAKE2B f64cc7e7e7147306cc153980caf1ae597b3f0f95c363b481d40fe44da12cf4bbd1759982b017d3f91cb980c557e35ad32133e98056097585f2012748de4764a4 SHA512 2c2b746a8253d2a27efed18d908fa8e41ad1014c369b54a7cbe26f6a8a5dbd43902eb2aba99410ee63b858a8c752239f0f1a5d90bfb166e77796e7b6fc0aa960
 DIST wt-4.13.2.tar.gz 11033297 BLAKE2B 0b050b840182714b346548b98131cd48229bfa40767a93b1b4b00df53ce1e96d3b44c088a2a317b7699f6c3425c50a5cba64b5e40e2c3e4d8fa66ccedd580149 SHA512 618fd4fce51eea0d6abacf86a1a395793ff535e4d17a4fb84fd792261a599f6cbe79ff47c4a3a9f160ac1a1f44f3e27a62cb15782f25251d029c777c91d82352
+DIST wt-4.13.3.tar.gz 11035398 BLAKE2B 5772f433fb009fb1e37f8df20d2d0ba0c445438697487dcb33841cbe30167b3449d2fe05343d602b8c3647e553c9d8c6b389ecde78dd2bf34966fa4d26248f0c SHA512 0ae5c2448404fca2583da5567dfa73db9fe7580fc17b6ae27e74b2cdeacfe37082b417847cf77a0b26c8efecca3ef3adc7f37e09f7eb2a67c84d2aab2a600566
diff --git a/dev-cpp/wt/wt-4.13.3.ebuild b/dev-cpp/wt/wt-4.13.3.ebuild
new file mode 100644
index 0000000000..aee94e2e11
--- /dev/null
+++ b/dev-cpp/wt/wt-4.13.3.ebuild
@@ -0,0 +1,131 @@
+# Copyright 2024-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake flag-o-matic
+
+DESCRIPTION="Wt, C++ Web Toolkit"
+HOMEPAGE="https://www.webtoolkit.eu/wt https://github.com/emweb/wt"
+SRC_URI="https://github.com/emweb/wt/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0/${PV}"
+KEYWORDS="~amd64"
+IUSE="doc +graphicsmagick mysql opengl +pango pdf postgres +sqlite ssl wttest"
+REQUIRED_USE="
+	pango? ( || ( graphicsmagick pdf ) )
+	opengl? ( graphicsmagick )
+"
+# TODO: auto-test with wttest
+RESTRICT="test"
+
+DEPEND="
+	dev-libs/boost:=
+	virtual/zlib:=
+	graphicsmagick? ( media-gfx/graphicsmagick:=[jpeg,png] )
+	mysql? (
+		virtual/mysql
+		|| (
+			dev-db/mariadb-connector-c
+			dev-db/mysql-connector-c
+		)
+	)
+	opengl? (
+		media-libs/glew:=
+		media-libs/libglvnd[X]
+	)
+	pango? (
+		dev-libs/glib:2
+		media-libs/fontconfig
+		x11-libs/pango
+	)
+	pdf? ( media-libs/libharu:= )
+	postgres? ( dev-db/postgresql )
+	sqlite? ( dev-db/sqlite:3 )
+	ssl? ( dev-libs/openssl:= )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	doc? (
+		app-text/doxygen
+		dev-qt/qttools:6[assistant]
+		dev-ruby/asciidoctor
+		media-gfx/graphviz[cairo]
+	)
+	virtual/pkgconfig
+"
+
+PATCHES=( "${FILESDIR}/wt-no-rundir.patch" )
+
+src_prepare() {
+	cmake_src_prepare
+
+	# remove bundled sqlite
+	rm -r src/Wt/Dbo/backend/amalgamation || die
+
+	if use doc; then
+		doxygen -u Doxyfile 2>/dev/null || die
+		doxygen -u examples/Doxyfile 2>/dev/null || die
+		sed -e "/^QHG_LOCATION/s|qhelpgenerator|/usr/$(get_libdir)/qt6/libexec/&|" \
+			-i Doxyfile || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DLIB_INSTALL_DIR=$(get_libdir)
+		-DBUILD_EXAMPLES=OFF
+		-DBUILD_TESTS=OFF
+		-DDOCUMENTATION_DESTINATION="share/doc/${PF}"
+		-DINSTALL_DOCUMENTATION=$(usex doc)
+		# will be deprecated
+		-DCONNECTOR_FCGI=OFF
+		-DCONNECTOR_HTTP=ON
+		-DENABLE_SSL=$(usex ssl)
+		-DENABLE_HARU=$(usex pdf)
+		-DENABLE_PANGO=$(usex pango)
+		-DENABLE_SQLITE=$(usex sqlite)
+		-DENABLE_POSTGRES=$(usex postgres)
+		-DENABLE_MYSQL=$(usex mysql)
+		-DENABLE_FIREBIRD=OFF
+		-DENABLE_LIBWTTEST=$(usex wttest)
+		# QT is only required for examples
+		-DENABLE_QT4=OFF
+		-DENABLE_QT5=OFF
+		-DENABLE_QT6=OFF
+		# requires shibboleth and opensaml, not in tree
+		-DENABLE_SAML=OFF
+		-DENABLE_OPENGL=$(usex opengl)
+		-DWT_WRASTERIMAGE_IMPLEMENTATION=$(usex graphicsmagick GraphicsMagick none)
+	)
+
+	if use mysql || use postgres || use sqlite; then
+		mycmakeargs+=( -DENABLE_LIBWTDBO=ON )
+		if use sqlite; then
+			mycmakeargs+=( -DUSE_SYSTEM_SQLITE3=ON )
+			# DboTest.C: In member function ‘void Sqlite3_Test_Suite::dbo_precision_test2::test_method()’
+			if use wttest; then
+			append-flags -fno-strict-aliasing
+			filter-lto
+			fi
+		fi
+	else
+		mycmakeargs+=( -DENABLE_LIBWTDBO=OFF )
+	fi
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	if use doc; then
+		find "${ED}" \( \
+			-iname '*.map' -o \
+			-iname '*.md5' \
+			\) -delete || die
+
+		docompress -x /usr/share/doc/${PF}/{examples,reference,tutorial}
+	fi
+}