dev-util/psautohint: add 2.4.0

Signed-off-by: Alessandro Barbieri <lssndrbarbieri@gmail.com>

dev-util/psautohint/Manifest

@@ -1,2 +1,3 @@
 DIST psautohint-2.3.0.tar.gz 181570 BLAKE2B 20127221ccbe890b363aba944ca19f6b126ba7c61f0b5e668288a12f93aebfe3541257e576f2ffce9bd935886f5cb9b4eb5c0dc08c0a8b1953484660fef8868a SHA512 943ac93ea4b0c188135cf2146803c36a3e5aa5b2e14924252281f22f6fc4190b935bdd72785107bbaf36d7503f48fc952fb32cd6965791c4ebebc699c0d7c5f5
+DIST psautohint-2.4.0.tar.gz 181009 BLAKE2B bb6ed5ae6b800742d8d1061004bfb49a84e3b9c99977a653ef8eeccf38d9c03261be5b735df20ee93dcf712b8b6ade7a2391937f327206fc2e01f2b5bcbe9022 SHA512 dfc29d020bedf8bd546e395743befb390e9fb01a3025aa10357a32724c9a78236acd57e05300aa26be630c9d43edab8bda731dc4f51c0a07d0bef79112d952aa
 DIST psautohint-testdata-1e4c5061d328105c4dcfcb6fdbc27ec49b3e9d23.tar.gz 21949984 BLAKE2B a5da67eb4b9f3d0ce5d86469bc0a5f771fa743198836db35121e9c62b66c8b8df00fef6e40e8832e33aee065fe3bdd0a24d1b590bce6fb66d7c43f6719236242 SHA512 03d4962958d3551ffdf99463d28723f6b43d42029843da1b40493b0bfc2e586ebf40db3a2497b36b5fde345de4b6998cfc1131c6fb4e8352b05fb59fc4e90e7f

dev-util/psautohint/psautohint-2.4.0.ebuild

@@ -0,0 +1,90 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+COMMIT="1e4c5061d328105c4dcfcb6fdbc27ec49b3e9d23"
+DISTUTILS_IN_SOURCE_BUILD=1
+EMESON_SOURCE="${S}/libpsautohint"
+PYTHON_COMPAT=( python3_{8..9} )
+
+inherit meson distutils-r1
+
+DESCRIPTION="A standalone version of AFDKO autohinter"
+HOMEPAGE="
+	https://github.com/adobe-type-tools/psautohint
+	https://pypi.org/project/psautohint/
+"
+SRC_URI="
+	https://github.com/adobe-type-tools/psautohint/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz
+	test? (
+		https://github.com/adobe-type-tools/psautohint-testdata/archive/${COMMIT}.tar.gz -> psautohint-testdata-${COMMIT}.tar.gz
+	)
+"
+KEYWORDS="~amd64"
+LICENSE="Apache-2.0"
+SLOT="0"
+
+# lxml, fs are indirect dependecies
+RDEPEND="
+	>=dev-python/fonttools-4.20[${PYTHON_USEDEP}]
+
+	dev-python/fs[${PYTHON_USEDEP}]
+	dev-python/lxml[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-bininpath.diff"
+	"${FILESDIR}/${PN}-2.3.0-no-build-library.patch"
+	"${FILESDIR}/${PN}-2.3.0-no-werror.patch"
+)
+
+distutils_enable_tests pytest
+
+pkg_setup() {
+	local _v=$(ver_cut 4)
+	_v="$(ver_cut 1-3)${_v:0:1}$(ver_cut 5)"
+	export SETUPTOOLS_SCM_PRETEND_VERSION="${_v/p/.post}"
+}
+
+src_unpack() {
+	default
+	if [ -d "${WORKDIR}/psautohint-testdata-${COMMIT}" ]; then
+		mv "${WORKDIR}/psautohint-testdata-${COMMIT}"/* "${S}/tests/integration/data/" || die
+	fi
+}
+
+src_configure() {
+	MESON_BUILD_DIR="${WORKDIR}/${P}-build"
+	BUILD_DIR="${MESON_BUILD_DIR}" meson_src_configure
+	distutils-r1_src_configure
+}
+
+src_compile() {
+	BUILD_DIR="${MESON_BUILD_DIR}" meson_src_compile
+	distutils-r1_src_compile
+}
+
+python_compile() {
+	esetup.py build_py build_ext --library-dirs "${MESON_BUILD_DIR}"
+}
+
+src_install() {
+	BUILD_DIR="${MESON_BUILD_DIR}" meson_src_install
+	distutils-r1_src_install
+	dodoc doc/*
+}
+
+python_test() {
+	local -x PATH="${BUILD_DIR}/test/scripts:${MESON_BUILD_DIR}l:${PATH}"
+	local -x LD_LIBRARY_PATH="${MESON_BUILD_DIR}"
+	distutils_install_for_testing
+	epytest -vv \
+		--deselect tests/integration/test_hint.py::test_hashmap_old_version \
+		--deselect tests/integration/test_mmhint.py::test_vfotf[tests/integration/data/vf_tests/CJKSparseVar.subset.hinted.otf] \
+		--deselect tests/integration/test_mmhint.py::test_vfotf[tests/integration/data/vf_tests/bug816.hinted.otf] \
+		--deselect tests/integration/test_cli.py::test_multi_outpath \
+		--deselect tests/integration/test_cli.py::test_multi_different_formats \
+		|| die
+}