From c21ddf37b57a88d458c375bf3f0bb27e05716b03 Mon Sep 17 00:00:00 2001
From: Alessandro Barbieri <lssndrbarbieri@gmail.com>
Date: Wed, 6 Apr 2022 22:14:15 +0200
Subject: [PATCH] dev-ml/vchan: initial import

Signed-off-by: Alessandro Barbieri <lssndrbarbieri@gmail.com>
---
 dev-ml/vchan/Manifest           |  1 +
 dev-ml/vchan/metadata.xml       | 15 ++++++++
 dev-ml/vchan/vchan-6.0.1.ebuild | 61 +++++++++++++++++++++++++++++++++
 3 files changed, 77 insertions(+)
 create mode 100644 dev-ml/vchan/Manifest
 create mode 100644 dev-ml/vchan/metadata.xml
 create mode 100644 dev-ml/vchan/vchan-6.0.1.ebuild

diff --git a/dev-ml/vchan/Manifest b/dev-ml/vchan/Manifest
new file mode 100644
index 0000000000..737b763b61
--- /dev/null
+++ b/dev-ml/vchan/Manifest
@@ -0,0 +1 @@
+DIST vchan-6.0.1.tbz 21954 BLAKE2B 01a8cea18ac7a94176f969323d765aadaf0ebb95ab781019caa7473fc1c0807bde3f432d81fbdd8d72261952ef36c5b7cd58fc6182d9477fe4db092bb523ec55 SHA512 8507095e49d2c47d3aa71a62a2856dea3bce0607ee3f03cd9c4a7a93b2a0f6b53788ef0345ce1193a10048251f4bd0f6d1af74ba2191682686ec463653b17622
diff --git a/dev-ml/vchan/metadata.xml b/dev-ml/vchan/metadata.xml
new file mode 100644
index 0000000000..19eeb5aaef
--- /dev/null
+++ b/dev-ml/vchan/metadata.xml
@@ -0,0 +1,15 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+    <maintainer type="person">
+        <email>lssndrbarbieri@gmail.com</email>
+        <name>Alessandro Barbieri</name>
+    </maintainer>
+    <upstream>
+        <remote-id type="github">mirage/vchan</remote-id>
+    </upstream>
+    <use>
+        <flag name="unix">Unix support</flag>
+        <flag name="xen">Xen support</flag>
+    </use>
+</pkgmetadata>
diff --git a/dev-ml/vchan/vchan-6.0.1.ebuild b/dev-ml/vchan/vchan-6.0.1.ebuild
new file mode 100644
index 0000000000..5bbb5e6066
--- /dev/null
+++ b/dev-ml/vchan/vchan-6.0.1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit dune multiprocessing
+
+MY_PN="ocaml-${PN}"
+
+DESCRIPTION="Pure OCaml implementation of the vchan shared-memory communication protocol"
+HOMEPAGE="https://github.com/mirage/ocaml-vchan"
+SRC_URI="https://github.com/mirage/${MY_PN}/releases/download/v${PV}/${P}.tbz"
+
+LICENSE="ISC"
+SLOT="0/${PV}"
+KEYWORDS="~amd64"
+IUSE="ocamlopt test unix xen"
+
+RDEPEND="
+	dev-ml/lwt
+	dev-ml/ppx_sexp_conv
+	dev-ml/io-page
+	dev-ml/mirage-flow
+	dev-ml/xenstore
+	dev-ml/xenstore-clients
+	dev-ml/sexplib
+	dev-ml/cstruct[ppx]
+
+	unix? (
+		dev-ml/xen-evtchn[unix]
+		dev-ml/xen-gnt[unix]
+		dev-ml/fmt
+	)
+	xen? ( dev-ml/mirage-xen )
+"
+DEPEND="
+	${RDEPEND}
+	test? (
+		dev-ml/cmdliner
+		dev-ml/ounit
+	)
+"
+
+RESTRICT="!test? ( test )"
+REQUIRED_USE="test? ( unix xen )"
+
+src_compile() {
+	local pkgs="vchan"
+	for u in xen unix ; do
+		if use ${u} ; then
+			 pkgs="${pkgs},vchan-${u}"
+		fi
+	done
+	dune build --only-packages "${pkgs}" -j $(makeopts_jobs) --profile release || die
+}
+
+src_install() {
+	dune_src_install vchan
+	use unix && dune_src_install vchan-unix
+	use xen && dune_src_install vchan-xen
+}