dev-libs/libsolv: add 0.7.32

Signed-off-by: Takuya Wakazono <pastalian46@gmail.com>

dev-libs/libsolv/Manifest

@@ -1,2 +1,3 @@
 DIST libsolv-0.7.30.tar.gz 762322 BLAKE2B 2d731d87fa71693d1af98f6290536d73bc398a319c63fd5444e5861a5eede58a5b966faa73af99f09d2c623314bd9fbca74700ba4827bb6f749ff0a450d133bc SHA512 65b385b6a303f40aeb49a67185469c9d554669a08e3c9529e5487fd31c7f4b25565899b2c20bbab69a44cfd7cc746b88d2b05c49d02c94a3cfa81f9142274f4e
 DIST libsolv-0.7.31.tar.gz 763630 BLAKE2B 5580376c23a8c5f72519b34b65800ecdffd2ed318ec929684a1de55f079f795e5118daca29d7d2510c30a8bd78e6db0ff450ff4db93d56a7a1c02fbe7a144e4c SHA512 96065ebec7e4d00f55a4e2f0fb1c519bf7b3220c47033071b183eea3f5b72499eda492e7b84754443f59dcbfd47e714808252f7a46de239ed16accdab4f66e4a
+DIST libsolv-0.7.32.tar.gz 773014 BLAKE2B 6df1ca570a8ddc417e692f50883b2722131def211a931ff50036f9540b7e0cc02a5aeacfcea93fa65b3c6fe0bf5cd2d9317b18eb97827657b4ddf9260a550cdd SHA512 4295f0489fd01bf6a42175cd8960319bd7b23f190ee7a8733d90d1a228535e3d825dc464622eeb3e36c6ea9a07460f6e87146b9813d7ff6cb9e3fc556c3a135c

dev-libs/libsolv/libsolv-0.7.32.ebuild

@@ -0,0 +1,53 @@
+# Copyright 2024-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="Library for solving packages and reading repositories"
+HOMEPAGE="https://github.com/openSUSE/libsolv"
+SRC_URI="https://github.com/openSUSE/libsolv/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="expat test zchunk"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	app-arch/bzip2
+	app-arch/rpm
+	app-arch/xz-utils
+	app-arch/zstd:=
+	sys-libs/zlib
+	expat? ( dev-libs/expat )
+	!expat? ( dev-libs/libxml2 )
+	zchunk? ( app-arch/zchunk )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+src_prepare() {
+	# remove forced CFLAGS -g -O2; bug 936869
+	sed "/CMAKE_C_FLAGS_${CMAKE_BUILD_TYPE^^}/d" -i CMakeLists.txt || die
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_RPMDB=ON
+		-DENABLE_RPMMD=ON
+		-DENABLE_RPMPKG_LIBRPM=ON
+		-DENABLE_COMPS=ON
+		-DENABLE_DEBIAN=OFF
+		-DENABLE_APK=OFF
+		-DENABLE_LZMA_COMPRESSION=ON
+		-DENABLE_BZIP2_COMPRESSION=ON
+		-DENABLE_ZSTD_COMPRESSION=ON
+		-DWITH_SYSTEM_ZCHUNK=$(usex zchunk)
+		-DWITH_LIBXML2=$(usex !expat)
+		-DENABLE_COMPLEX_DEPS=ON
+	)
+	cmake_src_configure
+}