phosh-base/phosh-mobile-settings: new package, add 0.36.0

Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>

phosh-base/phosh-mobile-settings/Manifest

@@ -0,0 +1,2 @@
+DIST phosh-mobile-settings-0.36.0.tar.xz 185628 BLAKE2B bed3c8dcd278e44e9beaec29c98e8ac5847377749ff18cc1e0d58f3f7178ae56b0642ae2c6ff89f5a724a9878da6660e6b60b2a4734a8d4d1feeb6f85dfa07db SHA512 f899105719908a044ac85d326288eec8dcaa2e5a8c27cffa1ad9354896f85c96b44f8114c08c4f7be6955faf79e32c7f26977a70c9d99a6b4654a8cd6d6db443
+DIST phosh-mobile-settings-0.36.0.tar.xz.asc 833 BLAKE2B 749625bae2a1bafc77ad5867b65a0a526dd5c9da25eebe9967fea816e30855f98e5bfec61c7cfcad3019fcb32290a262dbc108902bc969787e02d9be11e405f6 SHA512 bbe173ae4f34757963637c9e26bc0dd8d0ee60ea789a894b4732e572eaa25762605d79351f6e0e1b330e51dcc3dc9538b2e70ee98b679f46ea9d95df0e0906c0

phosh-base/phosh-mobile-settings/metadata.xml

@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>cyber+gentoo@sysrq.in</email>
+		<name>Anna</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="gnome-gitlab">guidog/phosh-mobile-settings</remote-id>
+	</upstream>
+</pkgmetadata>

phosh-base/phosh-mobile-settings/phosh-mobile-settings-0.36.0.ebuild

@@ -0,0 +1,56 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome2-utils meson verify-sig xdg
+
+DESCRIPTION="Mobile Settings App for phosh and related components"
+HOMEPAGE="https://gitlab.gnome.org/guidog/phosh-mobile-settings"
+SRC_URI="https://sources.phosh.mobi/releases/${PN}/${P}.tar.xz
+	verify-sig? ( https://sources.phosh.mobi/releases/${PN}/${P}.tar.xz.asc )"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-libs/glib-2.68:2
+	>=dev-libs/json-glib-1.6.2
+	>=dev-libs/wayland-1.14
+	>=gui-libs/gtk-4.4:4[wayland]
+	>=gui-libs/libadwaita-1.4:1
+	media-libs/gsound
+	phosh-base/phosh-shell
+	sys-apps/lm-sensors:=
+"
+DEPEND="${RDEPEND}
+	>=dev-libs/wayland-protocols-1.12
+"
+BDEPEND="
+	dev-libs/glib:2
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	dev-util/wayland-scanner
+	sys-devel/gettext
+	verify-sig? ( sec-keys/openpgp-keys-phosh )
+"
+
+VERIFY_SIG_OPENPGP_KEY_PATH="${BROOT}/usr/share/openpgp-keys/phosh.asc"
+
+QA_DESKTOP_FILE="usr/share/applications/mobi.phosh.MobileSettings.desktop"
+
+src_test() {
+	# No useful tests
+	:
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}