dev-lang/hare: add 0_pre20231127

Signed-off-by: Haelwenn (lanodan) Monnier <contact@hacktivis.me>

dev-lang/hare/Manifest

@@ -1,2 +1,3 @@
 DIST hare-009a8e873b688038aaf3c5e5e0b75c9205be56f5.tar.gz 728165 BLAKE2B ed3ecada9fc21e993548fa2b159b79ef3e8b537d3bd2ca54584127f315bf93e4440afa9cdf45f09aaac8665607a9e746b60ccd535a88aa538c6d7428b3d51e82 SHA512 16b8ef0a92c6ea8d6dabec283e4a7592fd301a11dd4bc837feff09f4f3743027efb615b2884eba2165ddfda197709324ed9fbb928d9d272f6585b3300c9d8582
 DIST hare-0cf443bbfb121fbf04d0d138161b6073a088bef9.tar.gz 725094 BLAKE2B 4ba04e73a70b4257dd8448a6a899058422bc0492f8f5598a1f705e4164a82a4e348f3877de710c17f2aebe909893d5d271242eb987dba37233a86fb881464f8c SHA512 9ac6322713366d7a7fa41ce86584e045a274c7a4b2389d96fe47d18133b233cc0a9f4ed41f2ed4c64f8d8e9601ed0dbe2cda6d89204e1add42f3f8a5a2688e94
+DIST hare-d94f355481a320fb2aec13ef62cb3bfe2416f5e4.tar.gz 716871 BLAKE2B 1805ca36c4e0faf581ad011d355eff63670e5dd13410e0aaaaee86c547ee7515a00577080c78e79c468274825e7905c386495e1b6520f60fd96d280f21e24044 SHA512 5638e213ac7dedd5a7a0c43bb481755e5cb5d9cbc227a0e08a53bbb4e9036e80111a5a7df2328bd4d1c0ede4cf703dd8a94f075a0850649b31770350223ecb96

dev-lang/hare/hare-0_pre20231127.ebuild

@@ -0,0 +1,55 @@
+# Copyright 2021-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+if [[ "${PV}" = 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://git.sr.ht/~sircmpwn/hare"
+	SLOT="0"
+else
+	EGIT_COMMIT="d94f355481a320fb2aec13ef62cb3bfe2416f5e4"
+	MY_P="${PN}-${EGIT_COMMIT}"
+	SRC_URI="https://git.sr.ht/~sircmpwn/hare/archive/${EGIT_COMMIT}.tar.gz -> ${MY_P}.tar.gz"
+	S="${WORKDIR}/${MY_P}"
+	SLOT="0/${PV}"
+	KEYWORDS="~amd64 ~arm64 ~riscv"
+fi
+
+DESCRIPTION="The Hare systems programming language"
+HOMEPAGE="https://harelang.org/"
+LICENSE="MPL-2.0 GPL-3"
+
+DEPEND="
+	~dev-lang/harec-0_pre20231128
+	~sys-devel/qbe-1.1-r1
+"
+BDEPEND="app-text/scdoc"
+RDEPEND="${DEPEND}"
+
+# hare and haredoc are built by hare
+QA_FLAGS_IGNORED="usr/bin/hare usr/bin/haredoc"
+
+src_configure() {
+	local target_arch
+	case ${ARCH} in
+		amd64 ) target_arch=x86_64 ;;
+		arm64 ) target_arch=aarch64 ;;
+		riscv ) target_arch=riscv64 ;;
+		* ) die "unsupported architecture: ${ARCH}" ;;
+	esac
+
+	cp config.example.mk config.mk || die
+	sed -i \
+		-e 's;=aarch64-;=;' \
+		-e 's;=riscv64-;=;' \
+		-e "s;^ARCH =.*;ARCH = ${target_arch};" \
+		-e 's;^AS =;AS ?=;' \
+		-e 's;^LD =;LD ?=;' \
+		-e 's;^AR =;AR ?=;' \
+		config.mk || die
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX="${EPREFIX}/usr" install
+}