dev-python/statmake: add 0.4.1, drop 0.3.0-r1

Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>

dev-python/statmake/statmake-0.4.1.ebuild

@@ -0,0 +1,39 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_SINGLE_IMPL=1
+DISTUTILS_USE_SETUPTOOLS=pyproject.toml
+PYTHON_COMPAT=( python3_{8..9} )
+inherit distutils-r1
+
+DESCRIPTION="Generate STAT tables for variable fonts from .stylespace files"
+HOMEPAGE="https://github.com/daltonmaag/statmake"
+SRC_URI="https://github.com/daltonmaag/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+KEYWORDS="~amd64"
+LICENSE="MIT"
+SLOT="0"
+
+RDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/cattrs[${PYTHON_USEDEP}]
+		dev-python/fonttools[${PYTHON_USEDEP}]
+	')
+"
+BDEPEND="test? (
+	$(python_gen_cond_dep 'dev-python/ufo2ft[${PYTHON_USEDEP}]')
+)"
+
+distutils_enable_tests pytest
+
+python_install() {
+	distutils-r1_python_install --skip-build
+	python_domodule "src/${PN}"
+}
+
+python_test() {
+	local -x PYTHONPATH="${S}/src:${PYTHONPATH}"
+	epytest
+}