From b4fde57e4a6ba8d229c69f32717dea043fe4fea2 Mon Sep 17 00:00:00 2001
From: Alessandro Barbieri <lssndrbarbieri@gmail.com>
Date: Wed, 14 Apr 2021 06:04:07 +0200
Subject: [PATCH] app-crypt/tomb: also install kdf-keys

Package-Manager: Portage-3.0.18, Repoman-3.0.3
Signed-off-by: Alessandro Barbieri <lssndrbarbieri@gmail.com>
---
 app-crypt/tomb/tomb-2.9-r1.ebuild | 103 ++++++++++++++++++++++++++++++
 1 file changed, 103 insertions(+)
 create mode 100644 app-crypt/tomb/tomb-2.9-r1.ebuild

diff --git a/app-crypt/tomb/tomb-2.9-r1.ebuild b/app-crypt/tomb/tomb-2.9-r1.ebuild
new file mode 100644
index 0000000000..509c6f9e32
--- /dev/null
+++ b/app-crypt/tomb/tomb-2.9-r1.ebuild
@@ -0,0 +1,103 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+MYP="${P^}"
+DESCRIPTION="Tomb :: File Encryption on GNU/Linux"
+HOMEPAGE="https://www.dyne.org/software/tomb"
+SRC_URI="https://files.dyne.org/tomb/releases/Tomb-${PV}.tar.gz"
+LICENSE="
+	GPL-3
+	gui? ( GPL-3+ )
+"
+SLOT="0"
+KEYWORDS="~amd64"
+#todo extras/desktop extras/qt-tray extras/kdf
+IUSE="gui test"
+#test require sudo, can't be done non interactively
+RESTRICT="test"
+PATCHES=( "${FILESDIR}/gtomb.patch" )
+DOCS=(
+	AUTHORS.txt
+	ChangeLog.txt
+	KNOWN_BUGS.txt
+	README.txt
+	doc/bertini_thesis.pdf
+	doc/HACKING.txt
+	doc/KEY_SPECIFICATIONS.txt
+	doc/LinuxHDEncSettings.txt
+	doc/Luks_on_disk_format.pdf
+	doc/New_methods_in_HD_encryption.pdf
+	doc/TKS1-draft.pdf
+	doc/tomb_manpage.pdf
+)
+S="${WORKDIR}/${MYP}"
+CDEPEND="dev-libs/libgcrypt"
+RDEPEND="
+	${CDEPEND}
+	app-admin/sudo
+	app-crypt/gnupg
+	app-crypt/pinentry
+	app-shells/zsh
+	sys-fs/cryptsetup
+	gui? ( gnome-extra/zenity )
+"
+DEPEND="${CDEPEND}"
+BDEPEND="
+	dev-python/pygments
+	sys-devel/gettext
+"
+
+src_compile() {
+	export PREFIX="${EPREFIX}/usr"
+	emake
+
+	pushd extras/kdf-keys || die
+	emake all
+	popd || die
+
+	#translations
+	pushd extras/translations || die
+	emake all
+	popd || die
+
+	#documentation
+	cd doc/literate || die
+	emake
+}
+
+src_install() {
+	default
+
+	#translations
+	export PREFIX="${ED}/usr"
+	pushd extras/translations || die
+	emake install
+	popd || die
+
+	#zenity gui
+	if use gui ; then
+		pushd extras/gtomb || die
+		dobin gtomb
+		newdoc README.md README-gtomb
+		popd || die
+	fi
+
+	pushd extras/kdf-keys || die
+	emake install
+	popd || die
+
+	#documentation
+	einstalldocs
+	cd doc/literate || die
+	insinto "/usr/share/doc/${PF}/html"
+	doins -r *.html *.css public
+}
+
+src_test() {
+	emake test
+
+	pushd extras/kdf-keys || die
+	emake test
+}