sys-power/ZenStates-Linux: new package

Package-Manager: Portage-3.0.18, Repoman-3.0.3
Signed-off-by: Alessandro Barbieri <lssndrbarbieri@gmail.com>

sys-power/ZenStates-Linux/Manifest

@@ -0,0 +1 @@
+DIST ZenStates-Linux-0bc27f4740e382f2a2896dc1dabfec1d0ac96818.tar.gz 3475 BLAKE2B ccbe505bc0f80b051fe589fbb0fecb5eb0dfb6861bb75a53c586406e35d8b9676428067386b6c0d77c806e20969f997d13593b34ffaa1d605e8f32a27a2121fb SHA512 832d0ae65aa2dfc9b1ef14f04bf75c9861acb0d84e9038f9de7c027b8b26a9cb27d2af011377bd47372424e2f918906d3d8ed7266f140790faacc0a19f419ee9

sys-power/ZenStates-Linux/ZenStates-Linux-0_p20170507.ebuild

@@ -0,0 +1,40 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{7,8,9} pypy3 )
+
+inherit linux-info python-single-r1
+
+DESCRIPTION="Dynamically edit AMD Ryzen processor P-States"
+HOMEPAGE="https://github.com/r4m0n/ZenStates-Linux"
+COMMIT=0bc27f4740e382f2a2896dc1dabfec1d0ac96818
+SRC_URI="https://github.com/r4m0n/ZenStates-Linux/archive/${COMMIT}.tar.gz -> ${PN}-${COMMIT}.tar.gz"
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="-* ~amd64"
+IUSE="togglecode"
+RDEPEND="
+	${PYTHON_DEPS}
+	togglecode? (
+		$(python_gen_cond_dep '
+			dev-python/portio[${PYTHON_USEDEP}]
+		')
+	)
+"
+DEPEND="${PYTHON_DEPS}"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+DOCS=( README.md )
+S="${WORKDIR}/${PN}-${COMMIT}"
+
+CONFIG_CHECK="X86_MSR"
+
+src_install() {
+	newsbin zenstates.py zenstates
+	python_fix_shebang "${ED}/usr/sbin/zenstates"
+	if use togglecode ; then
+		newsbin togglecode.py togglecode
+		python_fix_shebang "${ED}/usr/sbin/togglecode"
+	fi
+	einstalldocs
+}

sys-power/ZenStates-Linux/metadata.xml

@@ -0,0 +1,15 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<use>
+		<flag name="togglecode">Install the togglecode utility to turn on/off the Q-Code display on ASUS Crosshair VI Hero motherboards (and other boards with a compatible Super I/O chip)</flag>
+	</use>
+	<upstream>
+		<bugs-to>https://github.com/r4m0n/ZenStates-Linux/issues</bugs-to>
+		<maintainer>
+			<name>Thiago Ramon Gonçalves Montoya</name>
+			<email>thiagoramon@gmail.com</email>
+		</maintainer>
+		<remote-id type="github">r4m0n/ZenStates-Linux</remote-id>
+	</upstream>
+</pkgmetadata>