diff --git a/dev-python/av/Manifest b/dev-python/av/Manifest
new file mode 100644
index 0000000000..2b83d9662a
--- /dev/null
+++ b/dev-python/av/Manifest
@@ -0,0 +1 @@
+DIST av-17.0.0.gh.tar.gz 218778 BLAKE2B 215c2728779eae2592546e361787f4b0449f0efe7f81f3b4512d9affe8063a0f20a0cd449b6e8c365ff0b3f15a0919c524ecd16625f58be1351694000c8f34a8 SHA512 f65692fdbd2757a55cdd15077bafc3dd180ea046468d90c47a29fafbaad18d4aa44166dc463a6378afb6ab7edd5785045f5987b23b0c53deef60a0d08d92fb46
diff --git a/dev-python/av/av-17.0.0.ebuild b/dev-python/av/av-17.0.0.ebuild
new file mode 100644
index 0000000000..c898ae71d8
--- /dev/null
+++ b/dev-python/av/av-17.0.0.ebuild
@@ -0,0 +1,87 @@
+# Copyright 2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{12..14} )
+
+inherit distutils-r1
+
+MY_PN="PyAV"
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="Pythonic bindings for FFmpeg's libraries"
+HOMEPAGE="
+	https://pyav.basswood-io.com/docs/stable/
+	https://pypi.org/project/av/
+	https://github.com/PyAV-Org/PyAV/
+"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/PyAV-Org/PyAV.git"
+else
+	# pypi misses documentation
+	SRC_URI="https://github.com/PyAV-Org/PyAV/archive/v${PV}.tar.gz -> ${P}.gh.tar.gz"
+	KEYWORDS="~amd64"
+	S=${WORKDIR}/${MY_P}
+fi
+
+LICENSE="BSD"
+SLOT="0"
+
+IUSE="examples"
+
+BDEPEND="
+	virtual/pkgconfig
+	>=dev-python/cython-3.1.0[${PYTHON_USEDEP}]
+	test? (
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+	)
+"
+DEPEND="media-video/ffmpeg:="
+RDEPEND="
+	media-video/ffmpeg:=
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/pillow[${PYTHON_USEDEP}]
+"
+
+DOCS=( README.md {AUTHORS,CHANGELOG}.rst )
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+distutils_enable_sphinx docs dev-python/sphinx-copybutton
+
+src_prepare() {
+	default
+
+	# package directory must be deleted due to C ext.
+	# use PV instead of reading from pkg. dir.
+	sed -i \
+	-e 's|about = {}|about = {"__version__": "'"${PV}"'"}|' \
+	-e '/with open/,+2d' \
+	docs/conf.py || die
+}
+
+python_compile_all() {
+	rm -rf av || die
+
+	sphinx_compile_all
+}
+
+python_install_all() {
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+	distutils-r1_python_install_all
+}
+
+python_test() {
+	rm -rf av || die
+
+	epytest
+}
diff --git a/dev-python/av/metadata.xml b/dev-python/av/metadata.xml
new file mode 100644
index 0000000000..7be5d180b2
--- /dev/null
+++ b/dev-python/av/metadata.xml
@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>ghostyn678+git@gmail.com</email>
+		<name>dsaf</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">PyAV-Org/PyAV</remote-id>
+		<remote-id type="pypi">av</remote-id>
+		<doc>https://pyav.basswood-io.com/docs/stable/</doc>
+	</upstream>
+</pkgmetadata>