dev-python/asyncmy: add 0.2.7

Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>

dev-python/asyncmy/Manifest

@@ -1 +1,2 @@
 DIST asyncmy-0.2.5.gh.tar.gz 136467 BLAKE2B 1d5f687a5044653f00653d1b07129fdcb8465b7739e9d9d4b7481fbe3f406f0191c0642d46329e3639c8024a89ff70b8417bd26cdeaf804e278256e0bbb03eef SHA512 6777ccb9be483e2af996e3c814cb00a8db3b5d360c5543224265fd28c851bde4dfa9b81930c7928c10714f9ebed9134b1b5cc72f07c633fbb6eb4add7a10915d
+DIST asyncmy-0.2.7.gh.tar.gz 141090 BLAKE2B a16aa12dd68d7e7af36f854b0c05e03870c09087b85cd4154df30b2353fa1e6863def03e07873211594b5dce726b0ea18ceb796503cec83e62ebda9276498a40 SHA512 570add3f83088ed970305af26b17b639aed1954872f52310a4c24a588ce705481203ad5f0e82084d9d6a24a34913bc396b279c57c4b7b715ff2ef4840bc619c9

dev-python/asyncmy/asyncmy-0.2.7.ebuild

@@ -0,0 +1,73 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+PYTHON_REQ_USE="ssl"
+DISTUTILS_USE_PEP517=poetry
+inherit databases distutils-r1 optfeature
+
+DESCRIPTION="A fast asyncio MySQL driver"
+HOMEPAGE="
+	https://pypi.org/project/asyncmy/
+	https://github.com/long2ice/asyncmy
+"
+SRC_URI="https://github.com/long2ice/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.gh.tar.gz"
+TEST_S="${S}_test"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+BDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		$(emysql --get-depend)
+	)
+"
+
+distutils_enable_tests pytest
+
+src_unpack() {
+	default
+
+	cp -a "${S}" "${TEST_S}" || die
+	rm -r "${TEST_S}"/asyncmy || die
+}
+
+src_test() {
+	emysql --start
+	local sockfile=$(emysql --get-sockfile)
+
+	local myargs=(
+		--user=root
+		--socket="${sockfile}"
+		--silent
+		--execute="ALTER USER 'root'@'localhost' IDENTIFIED BY '123456';"
+	)
+
+	ebegin "Changing database password"
+	mysql "${myargs[@]}"
+	eend $? || emysql --die "Changing database password failed"
+
+	distutils-r1_src_test
+	emysql --stop
+}
+
+python_test() {
+	cd "${T}" || die
+	epytest "${TEST_S}"
+}
+
+python_install() {
+	distutils-r1_python_install
+	find "${ED}"/usr/lib -name '*.md' -delete || die
+	find "${ED}"/usr/lib -name LICENSE -delete || die
+}
+
+pkg_postinst() {
+	optfeature "sha256_password and caching_sha2_password auth methods" dev-python/cryprography
+}