dev-util/google-antigravity: add 2.18.1

Signed-off-by: Florian Albrechtskirchinger <falbrechtskirchinger@gmail.com>

dev-util/google-antigravity/Manifest

@@ -4,3 +4,5 @@ DIST google-antigravity-2.16.0_amd64.tar.gz 180508953 BLAKE2B 1f5d1bb35dbfe8dcb8
 DIST google-antigravity-2.16.0_arm64.tar.gz 178390335 BLAKE2B 70619294d818bd6c4bbb52af92c57ead1a8baa272270b3e8440e76c5740ccc08ca732b0195ae5ed41464c81451c76aa964d4dc0602fdf8d23df8f836df150dc4 SHA512 d5703bd88a247b7207a233b8506f576276ccda1a5f405ec791c5e870c6b63e70073e1d9d2ebe8d79976facdaf7cf9f7797249dca2eb1cc17f4416102787509b6
 DIST google-antigravity-2.17.0_amd64.tar.gz 179494137 BLAKE2B d759078b2e347b5c4cf3ed0386a1dc9dce9cf40a76e6f12db85e834143ca462c4f9bc2ebc14aa9514ab5c4df5f1e82746f0f98d329865481e49d127897f025a9 SHA512 06e9650f369dfc430c5558e3735e72392a93609efc299562b97cc9a22dae80dbb0d84720c90f7ecd045d2c71501f9d08f33ef2d45db13c0857e87781f8795b87
 DIST google-antigravity-2.17.0_arm64.tar.gz 177434632 BLAKE2B 10ceffd035f1ed35b6546822167c92818aa0ab587cfdeb6adf332406898dd54647932d172bbc6c639e133aa6989755fe4cfcb73df845e62ad21d17233601edbc SHA512 9e7b4d836b46068d3c736ee46c791105570adc5d628a8e3511544be68ba0e241208b1875b6718386e56e1dbd1efc1414727dcb1c37e6ad307689405a1582015e
+DIST google-antigravity-2.18.1_amd64.tar.gz 179722582 BLAKE2B d7688d35e28062c32d9219609e0fc233090877fb1cc0f824a32cd164e80ab26f938dda83d0cf71bf902191734b097b178d4d4c259bb24030812af9e22e56efdc SHA512 51013edad0856263a45c380c816af4034e59fef7ed711610627452bbc2fbc836c830a620c99a893f7782f52c66b7814b20b22877ca98ceae8b68387c5d767a78
+DIST google-antigravity-2.18.1_arm64.tar.gz 177636553 BLAKE2B 27aa0f82e6cb870a68a11558bdfdd31eaf841b45fa0f930d71ad58e347066c6251daa4c995ccf4d490f34cfc50bfbd78fa49bfb8ce309579c2f4b7e287435aa4 SHA512 edc05583ab84b52c12116c038bafcac8c76defe8f7c3c9dad8c704fb792d5fcb855cda4d39b933db2616e70ddbe696342777bf3caa0dab6dd1c987091471246a

dev-util/google-antigravity/google-antigravity-2.18.1.ebuild

@@ -0,0 +1,115 @@
+# Copyright 2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CHROMIUM_LANGS="af am ar bg bn ca cs da de el en-GB en-US es-419 es et fa fi
+		fil fr gu he hi hr hu id it ja kn ko lt lv ml mr ms nb nl pl pt-BR
+		pt-PT ro ru sk sl sr sv sw ta te th tr uk ur vi zh-CN zh-TW"
+
+inherit chromium-2 desktop optfeature pax-utils xdg
+
+EXECUTION_ID="4945794252537856"
+
+MY_PN="${PN#google-}"
+DESCRIPTION="Google Antigravity 2.0, a dedicated platform to work with agents"
+HOMEPAGE="https://antigravity.google/"
+BASE_URI="https://storage.googleapis.com/antigravity-public/antigravity-hub/${PV}-${EXECUTION_ID}"
+SRC_URI="
+	amd64? ( ${BASE_URI}/linux-x64/Antigravity.tar.gz -> ${P}_amd64.tar.gz )
+	arm64? ( ${BASE_URI}/linux-arm/Antigravity.tar.gz -> ${P}_arm64.tar.gz )
+"
+S="${WORKDIR}"
+
+# It's complicated...
+LICENSE="all-rights-reserved"
+SLOT="0"
+KEYWORDS="-* ~amd64 ~arm64"
+RESTRICT="bindist mirror strip"
+
+RDEPEND="
+	|| (
+		sys-apps/systemd
+		sys-apps/systemd-utils
+	)
+	>=app-accessibility/at-spi2-core-2.46.0:2
+	app-crypt/libsecret[crypt]
+	app-misc/ca-certificates
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	media-libs/alsa-lib
+	media-libs/libglvnd
+	media-libs/mesa
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	virtual/zlib:=
+	sys-process/lsof
+	x11-libs/cairo
+	x11-libs/gtk+:3
+	x11-libs/libdrm
+	x11-libs/libX11
+	x11-libs/libxcb
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libxkbcommon
+	x11-libs/libxkbfile
+	x11-libs/libXrandr
+	x11-libs/libXScrnSaver
+	x11-libs/pango
+	x11-misc/xdg-utils
+"
+
+QA_PREBUILT="*"
+QA_DESKTOP_FILE="usr/share/applications/${MY_PN}.*\\.desktop"
+
+AGY_HOME_BASE="opt/google"
+AGY_HOME="${AGY_HOME_BASE}/${MY_PN}"
+
+pkg_setup() {
+	chromium_suid_sandbox_check_kernel_config
+}
+
+src_unpack() {
+	default
+	mv "Antigravity-"* "${MY_PN}" || die
+}
+
+src_prepare() {
+	default
+
+	cd "${MY_PN}" || die
+
+	pushd locales > /dev/null || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+}
+
+src_install() {
+	cd "${MY_PN}" || die
+
+	mkdir -p "${ED}/${AGY_HOME}" || die
+	cp -r . "${ED}/${AGY_HOME}" || die
+
+	pax-mark m "${ED}/${AGY_HOME}/${MY_PN}"
+	fperms 0755 "/${AGY_HOME}/${MY_PN}"
+	dosym "/${AGY_HOME}/${MY_PN}" "/usr/bin/${MY_PN}"
+
+	fperms 4711 "/${AGY_HOME}/chrome-sandbox"
+
+	domenu "${FILESDIR}/${MY_PN}.desktop"
+	newicon -s scalable "${FILESDIR}/${MY_PN}.png" ${MY_PN}.png
+
+	insinto /usr/share/metainfo
+	doins "${FILESDIR}/${MY_PN}.metainfo.xml"
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	optfeature "desktop notifications" x11-libs/libnotify
+}