net-misc/searxng: new package, add 9999

Signed-off-by: Pavel Sobolev <contact@paveloom.dev>

net-misc/searxng/files/searxng.service

@@ -0,0 +1,15 @@
+[Unit]
+Description=SearXNG metasearch engine
+After=network.target
+
+[Service]
+Type=simple
+User=searxng
+Group=searxng
+WorkingDirectory=/var/lib/searxng
+ExecStart=/usr/bin/searxng-run
+Restart=on-failure
+RestartSec=5
+
+[Install]
+WantedBy=multi-user.target

net-misc/searxng/metadata.xml

@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person">
+    <name>Pavel Sobolev</name>
+    <email>contact@paveloom.dev</email>
+  </maintainer>
+  <upstream>
+    <bugs-to>https://github.com/searxng/searxng/issues</bugs-to>
+    <remote-id type="github">searxng/searxng</remote-id>
+  </upstream>
+</pkgmetadata>

net-misc/searxng/searxng-9999.ebuild

@@ -0,0 +1,66 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+DISTUTILS_SINGLE_IMPL=1
+PYTHON_COMPAT=( python3_{13..15} )
+
+EGIT_REPO_URI="https://github.com/searxng/searxng.git"
+
+inherit distutils-r1 git-r3 systemd
+
+DESCRIPTION="Free internet metasearch engine"
+HOMEPAGE="https://docs.searxng.org/"
+
+LICENSE="AGPL-3+"
+SLOT="0"
+
+RDEPEND="
+	acct-group/searxng
+	acct-user/searxng
+
+	$(python_gen_cond_dep '
+		dev-python/babel[${PYTHON_USEDEP}]
+		dev-python/flask-babel[${PYTHON_USEDEP}]
+		dev-python/flask[${PYTHON_USEDEP}]
+		dev-python/httpx-socks[${PYTHON_USEDEP}]
+		dev-python/httpx[${PYTHON_USEDEP}]
+		dev-python/isodate[${PYTHON_USEDEP}]
+		dev-python/jinja2[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+		dev-python/markdown-it-py[${PYTHON_USEDEP}]
+		dev-python/msgspec[${PYTHON_USEDEP}]
+		dev-python/pygments[${PYTHON_USEDEP}]
+		dev-python/python-dateutil[${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		dev-python/typer[${PYTHON_USEDEP}]
+		dev-python/typing-extensions[${PYTHON_USEDEP}]
+		dev-python/valkey[${PYTHON_USEDEP}]
+		dev-python/whitenoise[${PYTHON_USEDEP}]
+	')
+"
+BDEPEND="
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/aiounittest[${PYTHON_USEDEP}]
+			dev-python/mock[${PYTHON_USEDEP}]
+			dev-python/parameterized[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+EPYTEST_DESELECT=(
+	"tests/robot/test_webapp.py"
+	"tests/unit/test_utils.py::TestXPathUtils::test_eval_xpath_unregistered_function"
+)
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+src_install() {
+	distutils-r1_src_install
+
+	systemd_dounit "${FILESDIR}/searxng.service"
+}