gui-apps/fuzzel: add 1.9.0

Signed-off-by: Jonas Frei <freijon@pm.me>

gui-apps/fuzzel/Manifest

@@ -1 +1,2 @@
 DIST fuzzel-1.8.2.tar.gz 426759 BLAKE2B 107b59afa4bac54d27e679d484e3ff9c87c62c0934a6ed93e17e5c0c498d46c38174ad6e5c91aa1ef1018171f5833011b3ccb1173b59812219009257e4240b46 SHA512 53a7fd1e6fa44c702d7819970d0e55a35bd75ad5f61beb2de5e5f8007b864792af2dab93aba7defd063e117e7c3723fbfcd4df9ef0b3680ba2219aefde4a9982
+DIST fuzzel-1.9.0.tar.gz 431297 BLAKE2B a4e37e36c83a0666a3022057a199a72ca83ed5a074f550521738eac6b0dbd720c24aff6e5861105b05e9e949a5c057ded7331f8feceec2029c4a8adea80df583 SHA512 61390a6a1ac68eccd6a690e663b8710f931452b69b060e380310b7d0722c44b17d396ee44dc500f7ca8c23db98feb2e6303553d92d98c5d25ff9e1726086eb6d

gui-apps/fuzzel/fuzzel-1.9.0.ebuild

@@ -0,0 +1,54 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://codeberg.org/dnkl/fuzzel.git"
+else
+	SRC_URI="https://codeberg.org/dnkl/fuzzel/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+	S="${WORKDIR}/${PN}"
+fi
+
+DESCRIPTION="Application launcher for wlroots based Wayland compositors."
+HOMEPAGE="https://codeberg.org/dnkl/fuzzel"
+LICENSE="MIT"
+SLOT="0"
+IUSE="cairo png svg"
+
+DEPEND="
+	dev-libs/wayland
+	<media-libs/fcft-4.0.0
+	>=media-libs/fcft-3.0.0
+	x11-libs/libxkbcommon
+	x11-libs/pixman
+	cairo? ( x11-libs/cairo )
+	png? ( media-libs/libpng )
+	svg? ( gnome-base/librsvg )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	app-text/scdoc
+	>=dev-libs/tllist-1.0.1
+	dev-libs/wayland-protocols
+	dev-util/wayland-scanner
+"
+
+src_configure() {
+	local emesonargs=(
+		-Dpng-backend=$(usex png libpng none)
+		-Dsvg-backend=$(usex svg librsvg none)
+		$(meson_feature cairo enable-cairo)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	rm -rf "${ED}/usr/share/doc/fuzzel" || die
+}
+

gui-apps/fuzzel/metadata.xml

@@ -5,10 +5,10 @@
 		<name>Jonas Frei</name>
 		<email>freijon@pm.me</email>
 	</maintainer>
-	<!--<upstream>
+	<upstream>
 		<remote-id type="codeberg">dnkl/fuzzel</remote-id>
 		<bugs-to>https://codeberg.org/dnkl/fuzzel/issues</bugs-to>
-	</upstream>-->
+	</upstream>
 	<use>
 		<flag name="cairo">Required for rounded corners and SVG icons</flag>
 		<flag name="png">Enable support for PNG icons</flag>