dev-python/tooz: add 2.11.0

Signed-off-by: Alessandro Barbieri <lssndrbarbieri@gmail.com>

dev-python/tooz/Manifest

@@ -1 +1,2 @@
 DIST tooz-2.10.1.tar.gz 95627 BLAKE2B 046ac561f235c54be4a7984fb8d4f9c55e59a19284c9a2565d4001e78c55bf79e0247669e544dd8f4d4d78a3874282da92fbec05f615b561740cf7246042ecd8 SHA512 c968561ea950e2da3be47c4bb1bdc2cb5e0de62ce7f9bf371f455185b0587085b8224a853a183a9b1a8d5221ed054fa0b80da29fb6bfb1ac88b9793476f9c87c
+DIST tooz-2.11.0.tar.gz 95997 BLAKE2B a61199586e58ec6bb63133137c91445df9c284a65b91125fa73e8c19efa37a5b5da039be94bc73b983f7a83dfa2b34d4d6cd7eb702823fa5eaca9429984fc323 SHA512 feb9217908bb986aeeffe92ae765b948edb1c1311eeb011b19b7bfdccb9b94dec82139e6056bbdbbffa79b208fc9ef22d1e100f75d6e9c61f7352dee3523ab8f

dev-python/tooz/tooz-2.11.0.ebuild

@@ -0,0 +1,68 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..9} )
+
+inherit distutils-r1
+
+DESCRIPTION="Library centralizing the most common distributed primitives"
+HOMEPAGE="
+	https://opendev.org/openstack/tooz
+	https://pypi.org/project/tooz/
+	https://launchpad.net/python-tooz
+"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/pbr-1.6.1[${PYTHON_USEDEP}]
+	>=dev-python/stevedore-1.16.0[${PYTHON_USEDEP}]
+	>=dev-python/voluptuous-0.8.9[${PYTHON_USEDEP}]
+	>=dev-python/msgpack-0.4.0[${PYTHON_USEDEP}]
+	>=dev-python/fasteners-0.7[${PYTHON_USEDEP}]
+	>=dev-python/tenacity-3.2.1[${PYTHON_USEDEP}]
+	>=dev-python/futurist-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-utils-4.7.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-serialization-1.10.0[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	test? (
+		>=dev-python/subunit-0.0.18[${PYTHON_USEDEP}]
+		>=dev-python/testtools-1.4.0[${PYTHON_USEDEP}]
+		>=dev-python/fixtures-3.0.0[${PYTHON_USEDEP}]
+		>=dev-python/pifpaf-0.10.0[${PYTHON_USEDEP}]
+		>=dev-python/ddt-1.2.1[${PYTHON_USEDEP}]
+		>=dev-python/nose-1.3.7[${PYTHON_USEDEP}]
+
+		dev-python/etcd3[${PYTHON_USEDEP}]
+		dev-python/etcd3gw[${PYTHON_USEDEP}]
+		dev-python/pymemcache[${PYTHON_USEDEP}]
+		dev-python/pymysql[${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		dev-python/sysv_ipc[${PYTHON_USEDEP}]
+		dev-python/zake[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests nose
+
+python_prepare_all() {
+	# allow usage of renamed msgpack
+	sed -i '/^msgpack/d' requirements.txt || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	nosetests \
+		-e tooz.tests.test_coordination.TestAPI \
+		-e tooz.tests.test_memcache.TestMemcacheDriverFailures.test_client_failure_join \
+		-e tooz.tests.test_memcache.TestMemcacheDriverFailures.test_client_failure_leave \
+		-e tooz.tests.test_partitioner \
+		|| die
+}