dev-cpp/dpp: new package, add 10.0.21

Signed-off-by: Adrian Schollmeyer <nex+b-g-o@nexadn.de>

dev-cpp/dpp/Manifest

@@ -0,0 +1,2 @@
+DIST dpp-10.0.21-fix-install.patch 4090 BLAKE2B b4177190fb620952619ed5a0e4147a9adde4871f00643129b1f1140152718816cbcc1099c25e0b350c65ede56c2c5f373aeaf6345c382ba953c3ad32e9e3f2fd SHA512 8dd9a5f7db0097bc7de8e0a50253bc144786786331e3cfbfb00884925c41746e7a81bd2f87254d3bcc8d72bb820415bd92013cd0968950533bffa382bc53f279
+DIST dpp-10.0.21.tar.gz 13706441 BLAKE2B e7e68d4d121d17ad840790f14375ddc4e3c95c56ced03a90667b8b838205f3e46162bc9d60ea33d50a619335c7395318a9dd47583eddca3e73481879fe35f393 SHA512 a335886cdde5772b5602426e68c50d91e921cd127bcb918066c450b39fc5b0cf87ae692096140e76176d87265bd0d9de1fbb9d808a1f217dc2c8ef27210ad57f

dev-cpp/dpp/dpp-10.0.21.ebuild

@@ -0,0 +1,63 @@
+# Copyright 2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="Lightweight C++ Discord bot library"
+HOMEPAGE="https://dpp.dev/ https://github.com/brainboxdotcc/DPP"
+SRC_URI="
+	https://github.com/brainboxdotcc/DPP/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz
+	https://patch-diff.githubusercontent.com/raw/brainboxdotcc/DPP/pull/591.patch -> ${P}-fix-install.patch
+"
+
+LICENSE="Apache-2.0"
+# DPP is extremely ABI instable due to frequent changes in the Discord API
+# See https://github.com/brainboxdotcc/DPP/issues/207#issuecomment-1007030157
+SLOT="0/${PV}"
+KEYWORDS="~amd64"
+IUSE="voice"
+
+RDEPEND="
+	dev-libs/openssl:=
+	sys-libs/zlib:=
+
+	voice? (
+		dev-libs/libsodium:=
+		media-libs/opus
+	)
+"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	# Backport of the installation fixes, remove after 10.0.21
+	"${DISTDIR}/${P}-fix-install.patch"
+)
+
+S="${WORKDIR}/DPP-${PV}"
+
+DOCS=( "README.md" "SECURITY.md" )
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_SHARED_LIBS=true
+		-DBUILD_VOICE_SUPPORT=$(usex voice)
+		-DRUN_LDCONFIG=false
+		# Tests require network access
+		-DDPP_BUILD_TEST=false
+		-DDPP_NO_VCPKG=true
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	# Installation fix, remove after 10.0.21
+	mv \
+		"${ED}"/usr/$(get_libdir)/cmake/dpp/libdpp-config.cmake \
+		"${ED}"/usr/$(get_libdir)/cmake/dpp/dpp-config.cmake \
+		|| die "Failed to fix libdpp.cmake file name"
+}

dev-cpp/dpp/metadata.xml

@@ -0,0 +1,17 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>nex+b-g-o@nexadn.de</email>
+		<name>Adrian Schollmeyer</name>
+	</maintainer>
+	<maintainer type="person">
+		<email>samuel@seals-are-bouncy.tech</email>
+	</maintainer>
+	<use>
+		<flag name="voice">Enable voice-chat support</flag>
+	</use>
+	<upstream>
+		<remote-id type="github">brainboxdotcc/dpp</remote-id>
+	</upstream>
+</pkgmetadata>