diff --git a/app-text/OCRmyPDF/Manifest b/app-text/OCRmyPDF/Manifest
index 6570e79e15..f8ac66594d 100644
--- a/app-text/OCRmyPDF/Manifest
+++ b/app-text/OCRmyPDF/Manifest
@@ -1,2 +1,3 @@
 DIST OCRmyPDF-11.4.4.tar.gz 7883043 BLAKE2B 25d4f259c257884107c2fa76c2f662fc867528555ea47b3d3cabbbc3e9fd68bdb55ae4540556607ee31f534152b7c55076224c194e6299ab4bbd1b6f874752dc SHA512 198491f11764b68dc26877f73c815f1425b3bf730c5ada8319b1122ac525a3790e9e86a25b7965bf674197571960a76256984071e3f0b9a1507794dbb875340b
 DIST OCRmyPDF-11.4.5.tar.gz 7882974 BLAKE2B dd2c73e3aa78f0dadebcd25879aa315836e703bd089663a310af5b5231a03bf4cfe3acdbc4a658a99b92d585cd992134fdc1d3a12d7b2a74e205fe5b2ffa1b50 SHA512 4abf32733f520c0f8d99a9b1631d37ac339067b55756a9d9d4f0c182eca96f251ab7779d1c0af913891a57f3d103cc028ce3899dc263869ac6af3cf6f75e1ead
+DIST OCRmyPDF-11.5.0.tar.gz 7884615 BLAKE2B e0b298e011aa648b9d94febbead532d97af510e7281d1d0a8b828843627b9ad326a863e4bc7060a6fd746f114676449ea3575d94d60c30cf08873b06eb31b244 SHA512 e40d28a6b21e729077f34d3e1012965a3f162e4374c0e8c88acc05b143c14626829f25f2c91bb8995aca7609778fac78c91d89c6186109194fc1f211a3462e41
diff --git a/app-text/OCRmyPDF/OCRmyPDF-11.5.0.ebuild b/app-text/OCRmyPDF/OCRmyPDF-11.5.0.ebuild
new file mode 100644
index 0000000000..bf5a296b19
--- /dev/null
+++ b/app-text/OCRmyPDF/OCRmyPDF-11.5.0.ebuild
@@ -0,0 +1,67 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..8} )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit bash-completion-r1 distutils-r1
+
+DESCRIPTION="OCRmyPDF adds an OCR text layer to scanned PDF files"
+HOMEPAGE="https://github.com/jbarlow83/OCRmyPDF"
+SRC_URI="https://github.com/jbarlow83/OCRmyPDF/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+
+# This uses *a lot* of RAM, I have 32gb and these tests tried to use it all
+RESTRICT="test"
+IUSE="jbig2enc"
+
+RDEPEND="
+	app-text/ghostscript-gpl
+	app-text/tesseract
+	app-text/unpaper
+	dev-python/cffi[${PYTHON_USEDEP}]
+	dev-python/coloredlogs[${PYTHON_USEDEP}]
+	>=dev-python/pdfminer-six-20191110[${PYTHON_USEDEP}]
+	<=dev-python/pdfminer-six-20201018[${PYTHON_USEDEP}]
+	dev-python/pikepdf[${PYTHON_USEDEP}]
+	dev-python/pillow[${PYTHON_USEDEP}]
+	dev-python/pluggy[${PYTHON_USEDEP}]
+	dev-python/reportlab[${PYTHON_USEDEP}]
+	dev-python/tqdm[${PYTHON_USEDEP}]
+	media-gfx/img2pdf[${PYTHON_USEDEP}]
+	media-gfx/pngquant
+	media-libs/leptonica
+	virtual/python-cffi[${PYTHON_USEDEP}]
+	jbig2enc? ( media-libs/jbig2enc )
+"
+DEPEND="
+	test? (
+		dev-python/pytest-helpers-namespace[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		~dev-python/python-xmp-toolkit-2.0.1[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs --no-autodoc
+
+python_prepare_all() {
+	# do not depend on deprecated dep
+	sed -i -e '/pytest-runner/d' setup.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+src_install() {
+	distutils-r1_src_install
+
+	newbashcomp "${S}"/misc/completion/ocrmypdf.bash "${PN,,}"
+
+	insinto /usr/share/fish/vendor_completions.d
+	doins "${S}"/misc/completion/ocrmypdf.fish
+}