media-libs/libunicode: new package, add 0.6.0

Signed-off-by: David Roman <davidroman96@gmail.com>

media-libs/libunicode/Manifest

@@ -0,0 +1,2 @@
+DIST libunicode-0.6.0-ucd.zip 9020779 BLAKE2B 33507bb358933d5df1613a38598c2383f1942948186f7a0043f8c72577a798f47bf509a20f05e5dbaf73a34e6763f602481ab3af57afb66fc9d4f2aa1b19aaa2 SHA512 0fde45accf7068d639dcf8e739c7d9595c4cb3917f2e440cd0683aec1c0eebf5f4d0a975be09e5bc6297048a7031e84b5fcd4018ab29cc275801d770628b4439
+DIST libunicode-0.6.0.tar.gz 92750 BLAKE2B c79e51f56b1f62bc9cface69ee52ba5c8ba1f64fd69faa46f9e6dab02c17c9fc11946f7b14ce1879a1950a3fac423fbc81471e16bbc446824eee6f64432f2617 SHA512 49786d5aa1b69e9d4cfcb3b2723a2a12d0774166ae18f718f9212e1d833b28322b0510992c54ef9bff9a887600eaa32d8d67831021028d21a6cd80bb576c2aa6

media-libs/libunicode/libunicode-0.6.0.ebuild

@@ -0,0 +1,53 @@
+# Copyright 2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+UCD_VERSION="16.0.0"
+
+DESCRIPTION="Modern C++20 Unicode library"
+HOMEPAGE="https://github.com/contour-terminal/libunicode"
+SRC_URI="
+	https://github.com/contour-terminal/libunicode/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz
+	https://www.unicode.org/Public/${UCD_VERSION}/ucd/UCD.zip -> ${P}-ucd.zip
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	test? (
+		dev-cpp/catch
+	)
+"
+
+RDEPEND="${DEPEND}"
+BDEPEND="app-arch/unzip"
+
+src_unpack() {
+	unpack ${P}.tar.gz
+	mkdir -p "${P}/_ucd/ucd-${UCD_VERSION}" || die
+	unzip "${DISTDIR}/${P}-ucd.zip" -d "${P}/_ucd/ucd-${UCD_VERSION}" || die
+}
+
+src_prepare() {
+	sed -i '/test_main.cpp/d' src/libunicode/CMakeLists.txt || die
+	sed -i 's/Catch2::Catch2WithMain/Catch2Main Catch2::Catch2/g' src/libunicode/CMakeLists.txt || die
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCCACHE=Off
+		-DLIBUNICODE_TESTING=$(usex test)
+		-DLIBUNICODE_TOOLS=Off
+	)
+
+	cmake_src_configure
+}

media-libs/libunicode/metadata.xml

@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>davidroman96@gmail.com</email>
+		<name>David Roman</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">contour-terminal/libunicode</remote-id>
+	</upstream>
+</pkgmetadata>