dev-util/quilttools: Mailbox to quilt series converter (new package)

mb2q analyses the complete mailbox and collects various tags (Reviewed-by,
Acked-by, Tested-by) from replies to individual patches and to the cover
letter. If a tag is in a reply to the cover letter it is applied to all
patches which reference the cover letter.

Optionally the output can be redirected into a mailbox which can be applied
with git-am.

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Kurt Kanzenbach <kurt@kmk-computers.de>

dev-util/quilttools/quilttools-0.3.ebuild

@@ -0,0 +1,42 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=(python3_{6,7})
+
+inherit python-single-r1
+
+DESCRIPTION="Mailbox to quilt series converter"
+HOMEPAGE="https://git.kernel.org/pub/scm/linux/kernel/git/tglx/quilttools.git/about/"
+SRC_URI="https://git.kernel.org/pub/scm/linux/kernel/git/tglx/quilttools.git/snapshot/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc examples"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+BDEPEND="dev-python/sphinx"
+RDEPEND="${PYTHON_DEPS}
+	$(python_gen_cond_dep '
+		net-mail/notmuch[python,${PYTHON_MULTI_USEDEP}]
+	')"
+
+src_compile() {
+	emake -C Documentation man
+	use doc && emake -C Documentation html
+}
+
+src_install() {
+	dobin mb2q
+	doman Documentation/output/man/mb2q.1
+	python_fix_shebang "${ED}"
+
+	local DOCS=( README.md )
+	use doc && local HTML_DOCS=( Documentation/output/html/. )
+	einstalldocs
+
+	use examples && dodoc -r Documentation/examples
+}