dev-libs/libdwarf: add 0.4.1

Signed-off-by: Alessandro Barbieri <lssndrbarbieri@gmail.com>

dev-libs/libdwarf/libdwarf-0.4.1.ebuild

@@ -0,0 +1,45 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson
+
+DESCRIPTION="The DWARF Debugging Information Format"
+HOMEPAGE="
+	https://www.prevanders.net/dwarf.html
+	https://www.dwarfstd.org
+	https://github.com/davea42/libdwarf-code
+"
+SRC_URI="https://www.prevanders.net/${P}.tar.xz"
+
+LICENSE="LGPL-2.1 GPL-2 BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="doc dwarfexample dwarfgen +elf"
+
+DEPEND="
+	sys-libs/zlib
+	elf? ( virtual/libelf:= )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="doc? ( app-doc/doxygen )"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use dwarfgen)
+		$(meson_use dwarfexample)
+		$(meson_use doc)
+		$(meson_use elf libelf)
+	)
+	meson_src_configure
+}
+
+src_install(){
+	meson_src_install
+	dodoc AUTHORS README README.md ChangeLog* NEWS doc/*.pdf
+	if use doc; then
+		dodoc -r "${ED}/usr/share/doc/${PN}/html"
+		rm -r "${ED}/usr/share/doc/${PN}" || die
+	fi
+}