dev-python/pytest-steps: initial import

Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>

dev-python/pytest-steps/Manifest

@@ -0,0 +1 @@
+DIST pytest-steps-1.8.0.tar.gz 77136 BLAKE2B 7066cb7b586db6cc12fdc0f0da61c3207c32b9eef4dd667694d4db81fde849632dadf679bf44769cb307fcf5ab54b0878a9ad571c958f53dcb1ce6217c9a1651 SHA512 a8e159ba322c7d85dad1cc063781d79fec5a3ae3b135f341db2a254034fdbd004495bac6e5252f192771d3b34638a1abf24492594a612754d50be2d4a21e236e

dev-python/pytest-steps/metadata.xml

@@ -0,0 +1,17 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>cyber+gentoo@sysrq.in</email>
+		<name>Anna</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="pypi">pytest-steps</remote-id>
+		<remote-id type="github">smarie/python-pytest-steps</remote-id>
+		<doc>https://smarie.github.io/python-pytest-steps/</doc>
+		<maintainer>
+			<email>sylvain.marie@schneider-electric.com</email>
+			<name>Sylvain Marie</name>
+		</maintainer>
+	</upstream>
+</pkgmetadata>

dev-python/pytest-steps/pytest-steps-1.8.0.ebuild

@@ -0,0 +1,48 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+DOCS_BUILDER="mkdocs"
+DOCS_DEPEND="dev-python/mkdocs-material"
+DOCS_DIR="docs"
+inherit distutils-r1 docs
+
+DESCRIPTION="Create step-wise / incremental tests in pytest"
+HOMEPAGE="https://pypi.org/project/pytest-steps/ https://github.com/smarie/python-pytest-steps"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/makefun-1.5[${PYTHON_USEDEP}]
+	dev-python/wrapt[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		dev-python/pytest-cases[${PYTHON_USEDEP}]
+		dev-python/pytest-harvest[${PYTHON_USEDEP}]
+		dev-python/tabulate[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	sed "/pytest-runner/d" -i setup.cfg || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	docs_compile
+}
+
+python_test() {
+	epytest pytest_steps/tests --doctest-modules
+}