dev-python/gbinder: add 1.3.1, drop 1.1.2-r2

Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>

dev-python/gbinder/gbinder-1.3.1.ebuild

@@ -0,0 +1,39 @@
+# Copyright 2022-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{12..14} )
+
+DISTUTILS_USE_PEP517="setuptools"
+DISTUTILS_EXT=1
+
+inherit distutils-r1
+
+if [[ ${PV} != *9999* ]]; then
+	MY_PN="${PN}-python"
+	MY_P="${MY_PN}-${PV}"
+	S="${WORKDIR}/${MY_P}"
+	SRC_URI="https://github.com/waydroid/gbinder-python/archive/${PV}.tar.gz -> ${P}.gh.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+else
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/waydroid/gbinder-python.git"
+fi
+
+DESCRIPTION="Python bindings for dev-libs/gbinder"
+HOMEPAGE="https://github.com/waydroid/gbinder-python"
+LICENSE="GPL-3"
+SLOT="0"
+
+DEPEND="
+	>=dev-libs/gbinder-1.1.40
+	dev-libs/libglibutil
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	dev-python/cython[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests import-check