diff --git a/sci-electronics/kactus2/kactus2-9999.ebuild b/sci-electronics/kactus2/kactus2-9999.ebuild
new file mode 100644
index 0000000000..206e1429da
--- /dev/null
+++ b/sci-electronics/kactus2/kactus2-9999.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit xdg-utils
+
+DESCRIPTION="A open source IP-XACT-based tool"
+HOMEPAGE="
+	http://funbase.cs.tut.fi
+	https://github.com/kactus2/kactus2dev
+"
+
+if [[ ${PV} == "9999" ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/${PN}/${PN}dev.git"
+else
+	SRC_URI="https://github.com/${PN}/${PN}dev/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+	S="${WORKDIR}/${PN}dev-${PV}"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+
+DEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qthelp:5
+	dev-qt/qtprintsupport:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+"
+
+RDEPEND="
+	${DEPEND}
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-3.8.0-install.patch # Fix install problem
+)
+
+src_install() {
+	# Can't use default, set INSTALL_ROOT and workaround parallel install bug
+	emake -j1 INSTALL_ROOT="${D}" install
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+}