app-misc/fastfetch: add 0.568, 9999

Signed-off-by: Viorel Munteanu <ceamac.paragon@gmail.com>
2026-07-14 17:43:11 -04:00 · 2022-01-23 22:24:13 +02:00
parent 777940e6ea
commit a0edd8dcaf
3 changed files with 180 additions and 0 deletions
--- a/app-misc/fastfetch/Manifest
+++ b/app-misc/fastfetch/Manifest
@@ -1 +1,2 @@
 DIST fastfetch-0.554.tar.gz 177779 BLAKE2B 348b42b132c033db3830f74c2aab9ee40d88842c86ff395e14ba74863dbb353ad1f017ca9d8c136142e32c0492af193b735a6aab9bc973ace6d22162eb73d851 SHA512 1c4e8bd6ab4d21fec732007c3026ea690486ea5f3749115204235cff918e3e0479013ef19c65aeea6e38049a1d3fe0a05f1d1750cbae2b09e9caa64fe4945f2e
+DIST fastfetch-0.568.tar.gz 319886 BLAKE2B 5ac296319ff48cda0ba3a00dd0cc80bb19a632672ebf272ad1b35b5f3ca982c50bef1909cfa4274ce1e104458c9c4e73d2fda7dc714ab47d70fe341b0990441b SHA512 32704e78f6bd3c659b9090de949df2c63f755377760d95b5a3154bae72eb96baa0f0e2e1bcbcf226a81077c62089821884ed2ca30335fcfe1e77dd9a354854fd
--- a/app-misc/fastfetch/fastfetch-0.568.ebuild
+++ b/app-misc/fastfetch/fastfetch-0.568.ebuild
@@ -0,0 +1,90 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit bash-completion-r1 cmake
+
+DESCRIPTION="Like neofetch but faster"
+HOMEPAGE="https://github.com/LinusDierheimer/fastfetch"
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/LinusDierheimer/fastfetch.git"
+else
+	COMMIT="f72ec8a99f6021e95abce282668cce99fabd28c5"
+	VERSION_REV="f72ec8a"
+	SRC_URI="https://github.com/LinusDierheimer/fastfetch/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}/${PN}-${COMMIT}"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="X gnome pci vulkan wayland xcb xfce xrandr"
+
+# note - qa-vdb will always report errors because fastfetch loads the libs dynamically
+RDEPEND="
+	X? ( x11-libs/libX11 )
+	gnome? (
+		dev-libs/glib
+		gnome-base/dconf
+	)
+	pci? ( sys-apps/pciutils )
+	vulkan? ( media-libs/vulkan-loader )
+	wayland? ( dev-libs/wayland )
+	xcb? ( x11-libs/libxcb )
+	xfce? ( xfce-base/xfconf )
+	xrandr? ( x11-libs/libXrandr )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+REQUIRED_USE="xrandr? ( X )"
+
+# disable_check VAR lib
+disable_check() {
+	sed -i -e "
+		/pkg_check_modules ($1 /d
+		/message.*$2/d" CMakeLists.txt || die "Cannot disable $1"
+}
+
+src_configure() {
+	disable_check RPM librpm
+
+	use X || disable_check X11 x11
+	use gnome || (disable_check GIO gio- && disable_check DCONF dconf)
+	use pci || disable_check LIBPCI libpci
+	use vulkan || disable_check VULKAN vulkan
+	use wayland || disable_check WAYLAND wayland-client
+	use xcb || (disable_check XCB_RANDR xcb-randr && disable_check XCB xcb)
+	use xfce || disable_check XFCONF libxfconf
+	use xrandr || disable_check XRANDR xrandr
+
+	if [[ ${PV} != *9999 ]]; then
+		# version comes from git, fake it
+		VERSION_MAJOR="$(ver_cut 2)"
+		sed -i -e "
+			s/\(PROJECT_VERSION\) .*$/\1 \"r${VERSION_MAJOR}.${VERSION_REV}\")/
+			s/\(PROJECT_VERSION_MAJOR\) .*$/\1 \"${VERSION_MAJOR}\")/" CMakeLists.txt || die "Cannot patch version"
+	fi
+
+	cmake_src_configure
+}
+
+src_install() {
+	if [[ ${PV} == *9999 ]]; then
+		elog "REV=\"r$(git rev-list --count HEAD)\""
+		elog "COMMIT=\"$(git rev-parse HEAD)\""
+		elog "VERSION_REV=\"$(git rev-parse --short HEAD)\""
+	fi
+
+	pushd "${BUILD_DIR}" || die
+	dobin fastfetch
+	popd
+
+	newbashcomp completions/bash fastfetch
+	insinto /usr/share/${PN}/presets
+	doins presets/*
+
+	einstalldocs
+}
--- a/app-misc/fastfetch/fastfetch-9999.ebuild
+++ b/app-misc/fastfetch/fastfetch-9999.ebuild
@@ -0,0 +1,89 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit bash-completion-r1 cmake
+
+DESCRIPTION="Like neofetch but faster"
+HOMEPAGE="https://github.com/LinusDierheimer/fastfetch"
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/LinusDierheimer/fastfetch.git"
+else
+	COMMIT="f72ec8a99f6021e95abce282668cce99fabd28c5"
+	VERSION_REV="f72ec8a"
+	SRC_URI="https://github.com/LinusDierheimer/fastfetch/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}/${PN}-${COMMIT}"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="X gnome pci vulkan wayland xcb xfce xrandr"
+
+# note - qa-vdb will always report errors because fastfetch loads the libs dynamically
+RDEPEND="
+	X? ( x11-libs/libX11 )
+	gnome? (
+		dev-libs/glib
+		gnome-base/dconf
+	)
+	pci? ( sys-apps/pciutils )
+	vulkan? ( media-libs/vulkan-loader )
+	wayland? ( dev-libs/wayland )
+	xcb? ( x11-libs/libxcb )
+	xfce? ( xfce-base/xfconf )
+	xrandr? ( x11-libs/libXrandr )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+REQUIRED_USE="xrandr? ( X )"
+
+# disable_check VAR lib
+disable_check() {
+	sed -i -e "
+		/pkg_check_modules ($1 /d
+		/message.*$2/d" CMakeLists.txt || die "Cannot disable $1"
+}
+
+src_configure() {
+	disable_check RPM librpm
+
+	use X || disable_check X11 x11
+	use gnome || (disable_check GIO gio- && disable_check DCONF dconf)
+	use pci || disable_check LIBPCI libpci
+	use vulkan || disable_check VULKAN vulkan
+	use wayland || disable_check WAYLAND wayland-client
+	use xcb || (disable_check XCB_RANDR xcb-randr && disable_check XCB xcb)
+	use xfce || disable_check XFCONF libxfconf
+	use xrandr || disable_check XRANDR xrandr
+
+	if [[ ${PV} != *9999 ]]; then
+		# version comes from git, fake it
+		VERSION_MAJOR="$(ver_cut 2)"
+		sed -i -e "
+			s/\(PROJECT_VERSION\) .*$/\1 \"r${VERSION_MAJOR}.${VERSION_REV}\")/
+			s/\(PROJECT_VERSION_MAJOR\) .*$/\1 \"${VERSION_MAJOR}\")/" CMakeLists.txt || die "Cannot patch version"
+	fi
+
+	cmake_src_configure
+}
+
+src_install() {
+	if [[ ${PV} == *9999 ]]; then
+		elog "REV=\"r$(git rev-list --count HEAD)\""
+		elog "COMMIT=\"$(git rev-parse HEAD)\""
+		elog "VERSION_REV=\"$(git rev-parse --short HEAD)\""
+	fi
+
+	pushd "${BUILD_DIR}" || die
+	dobin fastfetch
+	popd
+
+	newbashcomp completions/bash fastfetch
+	insinto /usr/share/${PN}/presets
+	doins presets/*
+
+	einstalldocs
+}