media-sound/Tauon: add 8.1.2

Signed-off-by: David Roman <davidroman96@gmail.com>

media-sound/Tauon/Manifest

@@ -1,2 +1,3 @@
 DIST Tauon-8.0.1.tar.gz 1668223 BLAKE2B 3d32d839440067ad11ddf76f6b188b82ba50ac6e45624fb8f96ca8f70721c1b6cf111092b76f92f7b06e57120555522dc5752ba2fd4bc7ce20133b7c7e358e37 SHA512 d7a17df12ea259a4ef4116f3690b5b0ac6a259e079747cfcf1fbef24f45b77024260d133a3a1d75ef371c3c0ddc6be36bed1dee440609a94ebdaabd2dc2828f7
 DIST Tauon-8.1.0.tar.gz 1690926 BLAKE2B 38b7932c06b765041c3682da3031d426c9b3a3448dbd3516c708b77893a9611ea0afcc12c7f1275fd8207687f8142535976b01353d0ec668c43d1bc0871fd2e6 SHA512 5c403f77e7eff02d329b312342d9a9e2117c184b418859c194d3a12048f8048c5471a43eb0070d43500af29dcf50a19eeb03e77cb4c6213aa1b7731826455d12
+DIST Tauon-8.1.2.tar.gz 1691830 BLAKE2B 3fd383cbad6328baedbecf1d517e913010d84b38852a4e5d016cecb6ed7bf2f267f0ef56063906053b7bacb85c019c45c445b2c516eb81041e6d108d0947328c SHA512 e90fb76cb06695e2db83d70ebd9418dc55bd9dd3d0faa8ff7de5c1130a3a1291fa63eacbb3a52faea9edf5351e76d2d32d67136f9124160e5d85bc3c369a13ae

media-sound/Tauon/Tauon-8.1.2.ebuild

@@ -0,0 +1,108 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PLOCALES="cs de es fr_FR hu id it ja_JP nb_NO pl pt pt_BR pt_PT ru sv tr zh_CN"
+
+PYTHON_COMPAT=( python3_{12..13} )
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+
+inherit desktop distutils-r1 optfeature plocale xdg
+
+DESCRIPTION="The desktop music player of today!"
+HOMEPAGE="https://tauonmusicbox.rocks/"
+
+if [[ ${PV} == *9999 ]]; then
+	EGIT_SUBMODULES=()
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/Taiko2k/${PN}"
+else
+	SRC_URI="https://github.com/Taiko2k/Tauon/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="GPL-3"
+SLOT="0"
+
+PHAZOR_DEPS="
+	dev-libs/miniaudio
+	media-libs/flac:=
+	media-libs/game-music-emu
+	media-libs/libopenmpt
+	media-libs/opus
+	media-libs/opusfile
+	media-libs/libsamplerate
+	media-libs/libvorbis
+	media-sound/mpg123
+	media-sound/wavpack
+	sci-libs/kissfft[-cpu_flags_x86_sse]
+"
+
+DEPEND="
+	dev-python/aiohttp[${PYTHON_USEDEP}]
+	dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+	dev-python/musicbrainzngs[${PYTHON_USEDEP}]
+	dev-python/natsort[${PYTHON_USEDEP}]
+	dev-python/pillow[${PYTHON_USEDEP}]
+	dev-python/pysdl3[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/setproctitle[${PYTHON_USEDEP}]
+	dev-python/send2trash[${PYTHON_USEDEP}]
+	dev-python/unidecode[${PYTHON_USEDEP}]
+	media-video/ffmpeg
+	media-libs/mutagen[${PYTHON_USEDEP}]
+	media-libs/sdl3-image
+
+	${PHAZOR_DEPS}
+"
+
+RDEPEND="
+	${DEPEND}
+
+	dev-libs/libayatana-appindicator
+	media-sound/mpg123-base
+	x11-libs/libnotify
+"
+
+BDEPEND="sys-devel/gettext"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-7.9.0-phazor-build.patch"
+	"${FILESDIR}/${PN}-8.1.0-fix-locale-path.patch"
+)
+
+src_compile() {
+	distutils-r1_src_compile
+
+	build_locale() {
+		msgfmt -o "locale/${1}/LC_MESSAGES/tauon.mo" "locale/${1}/LC_MESSAGES/tauon.po" || die
+	}
+
+	plocale_for_each_locale build_locale
+}
+
+python_install() {
+	distutils-r1_python_install
+
+	install_locale() {
+		insinto "/usr/share/locale/${1}/LC_MESSAGES"
+		doins "locale/${1}/LC_MESSAGES/tauon.mo"
+	}
+
+	plocale_for_each_locale install_locale
+
+	sed -i 's/Exec=tauon/Exec=tauonmb/g' extra/tauonmb.desktop || die
+	domenu extra/tauonmb.desktop
+	doicon -s scalable extra/tauonmb.svg
+
+}
+
+pkg_postinst() {
+	optfeature "Chinese searches support" app-i18n/opencc[python]
+	optfeature "last fm support" dev-python/pylast
+	optfeature "PLEX support" dev-python/plexapi
+	optfeature "Spotify support" dev-python/tekore
+
+	xdg_pkg_postinst
+}