dev-nim/cligen: add 1.9.6, drop 1.9.3

Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>

dev-nim/cligen/cligen-1.9.6.ebuild

@@ -0,0 +1,39 @@
+# Copyright 2022-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit nimble
+
+DESCRIPTION="Infer & generate command-line interface/option/argument parser"
+HOMEPAGE="
+	https://c-blake.github.io/cligen/
+	https://github.com/c-blake/cligen
+"
+SRC_URI="https://github.com/c-blake/${PN}/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="ISC MIT"
+SLOT="${PV}"
+KEYWORDS="~amd64"
+IUSE="test toml"
+RESTRICT="!test? ( test )"
+
+RDEPEND="toml? ( dev-nim/parsetoml )"
+DEPEND="${RDEPEND}
+	test? ( dev-nim/parsetoml )
+"
+
+DOCS=( configs {MOTIVATION,README,RELEASE-NOTES,TODO}.md )
+
+set_package_url "https://github.com/c-blake/cligen"
+
+src_test() {
+	emake test V=1 NIM_EXTRA="--processing:off"
+}
+
+src_install() {
+	docompress -x /usr/share/doc/${PF}/examples
+	dodoc -r examples
+
+	nimble_src_install
+}