gui-apps/1password: add 8.10.28

Signed-off-by: Viorel Munteanu <ceamac@gentoo.org>

gui-apps/1password/1password-8.10.28.ebuild

@@ -0,0 +1,72 @@
+# Copyright 2023-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit optfeature rpm xdg
+
+DESCRIPTION="The world’s most-loved password manager"
+HOMEPAGE="https://1password.com"
+SRC_URI="amd64? ( https://downloads.1password.com/linux/rpm/stable/x86_64/${P}.x86_64.rpm )"
+S="${WORKDIR}"
+
+LICENSE="all-rights-reserved"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RESTRICT="mirror strip test bindist"
+
+DEPEND="
+	x11-misc/xdg-utils
+	acct-group/1password
+"
+RDEPEND="
+	${DEPEND}
+	app-accessibility/at-spi2-core:2
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	media-libs/alsa-lib
+	media-libs/mesa
+	net-print/cups
+	sys-apps/dbus
+	sys-apps/systemd-utils
+	sys-libs/zlib
+	x11-libs/cairo
+	x11-libs/gtk+:3
+	x11-libs/libdrm
+	x11-libs/libX11
+	x11-libs/libxcb
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libxkbcommon
+	x11-libs/libXrandr
+	x11-libs/pango
+"
+
+src_unpack() {
+	rpm_unpack ${P}.x86_64.rpm
+}
+
+QA_PREBUILT="opt/1Password/*"
+
+src_install() {
+	cp -ar opt "${ED}" || die "Install failed!"
+	cp -ar usr "${ED}" || die "Install failed!"
+
+	fowners root:1password /opt/1Password/1Password-BrowserSupport || die
+	fperms 4755 /opt/1Password/chrome-sandbox
+	fperms 2755 /opt/1Password/1Password-BrowserSupport
+
+	dosym -r /opt/1Password/1password /usr/bin/1password
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	optfeature "cli support" app-misc/1password-cli
+	optfeature "policykit support" sys-auth/polkit
+}

gui-apps/1password/Manifest

@@ -1 +1,2 @@
 DIST 1password-8.10.16.x86_64.rpm 101643244 BLAKE2B 8ac9c3ebf515347297addf5fa3ca3183a5e4a97160276cdd1ec968970b2878ad2111a1bc8ecc8bf2e82b287b3ec53c6e51753b5aed101b890ac63290da7dd6fd SHA512 5670318cf0f4745d62e49b932edd98f721a3c1c9fd0b6b86791d0da244f1718bf86485602787373a33f8e496eb533fb475a93ae67244b45ec08d6eb857d75e86
+DIST 1password-8.10.28.x86_64.rpm 139002692 BLAKE2B 2c2713e7df8020ab348cbeefc094ec79239ab5481c38798f67f21b86eb49a0701c71b11b11a3f04fecaf04589bee6df8dfb80ee9a8aba8f6ab565187e5f351a7 SHA512 b6e24e7b4c2b2940e1d798ab162d71f8926a1f1ec6310d3112f44af35bb17d70602c4bafcb6ed7358ba10516d1991765089e7ee5231d3bea6935c4f359755095