gui-libs/xdg-desktop-portal-hyprland: add 0.3.1

Signed-off-by: Remigiusz Micielski <remigiusz.micielski@gmail.com>

gui-libs/xdg-desktop-portal-hyprland/Manifest

@@ -1 +1,2 @@
 DIST xdg-desktop-hyprland-0.3.0.tar.gz 50728 BLAKE2B ea139dd5d1f51e004494cdd5eb80b154a95d64dc40100e9f7da99808e9f24018dc1de4e4572906521beb850d22b7fcc4967c63993c274d2c8e550b11e7eb4367 SHA512 f303fd0fb5ea09c7e12b6435f4113d7d5d9bbe0a785f2da9beaf7a6f9184954a53a1ad5be2c865e9e7071f5079223e512038328598ac5a64238c307741aad974
+DIST xdg-desktop-hyprland-0.3.1.tar.gz 50517 BLAKE2B dddbf1b71da391aa9d6d030fd9bdeb7819e44f6d283aec75cea2d37c0d27468fe633f235679f62b9ca1b98d919c449c0006d40495fb60a3627270e7acccca087 SHA512 53fd43621aa4960f2fa3272feec062917efa6a74f59670fc95519e13ae37e92ee8881dadf6ac8c397225ea2bcf4f1fabd87bc7bbe20c035e97dd7654398ac711

gui-libs/xdg-desktop-portal-hyprland/xdg-desktop-portal-hyprland-0.3.1.ebuild

@@ -0,0 +1,73 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson
+
+DESCRIPTION="xdg-desktop-portal backend for hyprland"
+HOMEPAGE="https://github.com/hyprwm/xdg-desktop-portal-hyprland"
+
+if [[ ${PV} == 9999 ]]; then
+	EGIT_REPO_URI="https://github.com/hyprwm/xdg-desktop-portal-hyprland.git"
+	inherit git-r3
+else
+	KEYWORDS="~amd64"
+	SRC_URI="https://github.com/hyprwm/xdg-desktop-portal-hyprland/archive/refs/tags/v${PV}.tar.gz \
+		-> xdg-desktop-hyprland-${PV}.tar.gz"
+fi
+
+LICENSE="MIT"
+SLOT="0/9999"
+IUSE="elogind systemd"
+REQUIRED_USE="?? ( elogind systemd )"
+
+DEPEND="
+	>=media-video/pipewire-0.3.41:=
+	dev-libs/inih
+	dev-libs/wayland
+	dev-qt/qtbase
+	dev-qt/qtcore
+	dev-qt/qtgui
+	dev-qt/qtwayland:6
+	dev-qt/qtwidgets
+	media-libs/mesa
+	sys-apps/util-linux
+	x11-libs/libdrm
+	|| (
+		systemd? ( >=sys-apps/systemd-237 )
+		elogind? ( >=sys-auth/elogind-237 )
+		sys-libs/basu
+	)
+"
+RDEPEND="
+	${DEPEND}
+	sys-apps/xdg-desktop-portal
+"
+BDEPEND="
+	>=dev-libs/wayland-protocols-1.24
+	dev-libs/hyprland-protocols
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local emesonargs=()
+	if use systemd; then
+		emesonargs+=(-Dsd-bus-provider=libsystemd)
+	elif use elogind; then
+		emesonargs+=(-Dsd-bus-provider=libelogind)
+	else
+		emesonargs+=(-Dsd-bus-provider=basu)
+	fi
+	meson_src_configure
+}
+
+src_compile() {
+	meson_src_compile
+	emake -C hyprland-share-picker all
+}
+
+src_install() {
+	meson_src_install
+	dobin "${S}/hyprland-share-picker/build/hyprland-share-picker"
+}