From 98f274e5627d78fe8b6755872e4837d514b65e72 Mon Sep 17 00:00:00 2001
From: Alessandro Barbieri <lssndrbarbieri@gmail.com>
Date: Tue, 7 Jun 2022 23:50:41 +0200
Subject: [PATCH] dev-libs/cubew: new package, add 4.7

Signed-off-by: Alessandro Barbieri <lssndrbarbieri@gmail.com>
---
 dev-libs/cubew/Manifest         |  1 +
 dev-libs/cubew/cubew-4.7.ebuild | 51 +++++++++++++++++++++++++++++++++
 dev-libs/cubew/metadata.xml     | 13 +++++++++
 3 files changed, 65 insertions(+)
 create mode 100644 dev-libs/cubew/Manifest
 create mode 100644 dev-libs/cubew/cubew-4.7.ebuild
 create mode 100644 dev-libs/cubew/metadata.xml

diff --git a/dev-libs/cubew/Manifest b/dev-libs/cubew/Manifest
new file mode 100644
index 0000000000..1903bd55e3
--- /dev/null
+++ b/dev-libs/cubew/Manifest
@@ -0,0 +1 @@
+DIST cubew-4.7.tar.gz 1347200 BLAKE2B 5083ca74a1125e81bc2a5493bb26119bbb478a16847cc4ef3cf6afbad9289bcffff8a0bc2b480b9cf711560d33f5a7fa207b7a20ffde343eac8e05385d3e778f SHA512 21bfef1fadb93d6089503ee86b54bbd2aca67a3a0f33ad64a1bd50b507dbf1a3047b4a454f9225f0379353d31f74e4b6a3a6851b776f44bd0ececb3322466f3d
diff --git a/dev-libs/cubew/cubew-4.7.ebuild b/dev-libs/cubew/cubew-4.7.ebuild
new file mode 100644
index 0000000000..9fc2ad4731
--- /dev/null
+++ b/dev-libs/cubew/cubew-4.7.ebuild
@@ -0,0 +1,51 @@
+# Copyright 2019-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="High performance C Writer library"
+HOMEPAGE="https://www.scalasca.org/scalasca/software/cube-4.x"
+SRC_URI="https://apps.fz-juelich.de/scalasca/releases/cube/${PV}/dist/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="advanced-memory memory-tracking memory-tracing +zlib"
+
+RDEPEND="
+	sys-libs/binutils-libs
+	zlib? ( sys-libs/zlib )
+"
+DEPEND="${RDEPEND}"
+
+REQUIRED_USE="
+	memory-tracking? ( advanced-memory )
+	memory-tracing? ( advanced-memory )
+"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myconf=(
+		--disable-platform-mic
+		$(use_with advanced-memory)
+		$(use_with memory-tracking)
+		$(use_with memory-tracing)
+		$(use_with zlib compression)
+	)
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	mv "${ED}/usr/share/doc/cubew" "${ED}/usr/share/doc/${PF}" || die
+	dodoc OPEN_ISSUES README
+	docompress -x "${ED}/usr/share/doc/${PF}/example"
+	find "${ED}" -name '*.la' -delete || die
+	find "${ED}" -name '*.a' -delete || die
+}
diff --git a/dev-libs/cubew/metadata.xml b/dev-libs/cubew/metadata.xml
new file mode 100644
index 0000000000..01baafc10e
--- /dev/null
+++ b/dev-libs/cubew/metadata.xml
@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>lssndrbarbieri@gmail.com</email>
+		<name>Alessandro Barbieri</name>
+	</maintainer>
+	<use>
+		<flag name="advanced-memory">Enables advanced memory features such as usage of an external memory allocator</flag>
+		<flag name="memory-tracking">Enables internal memory tracking</flag>
+		<flag name="memory-tracing">Enables internal memory tracing more intensive memory usage report.</flag>
+	</use>
+</pkgmetadata>