games-util/ProtonUp-Qt: add 2.13.0

Signed-off-by: Takuya Wakazono <pastalian46@gmail.com>

games-util/ProtonUp-Qt/Manifest

@@ -1,2 +1,3 @@
 DIST ProtonUp-Qt-2.11.1.tar.gz 944076 BLAKE2B bf2c1bd63e81b8fef15e78132b652e9b2ea44fe837ebaccd5eb12a719ef8199f013865f92dcf57e40bf5464f39d6fe7d69dc4e7eb4c5f9edc4d59d4fcace3087 SHA512 b839880656e8957c1b7d5d99a68b2809e208308ceb45df907e04bd1bd0ee24f695f79b3c7ba7c3ed12b9ed7e8106aed68afb361ff81181a556000c5717b25de7
 DIST ProtonUp-Qt-2.12.0.tar.gz 1007595 BLAKE2B 368dfd40c3f9cf5c6d794499af2f883e36b84ddad1b9465a5325d328bdfae4c1ac88b58846fa1309dfa2ef431b4df2402b9865b8ce3ac086b8d5e838b61199f2 SHA512 9efb608e3b4cde605351136811a2b201d0d05687de60dee8ad3d8fe932ade2b3298106a0d43bef933aca952ab393ed4c9817ddb4656bdb44a51f0594becfb6b4
+DIST ProtonUp-Qt-2.13.0.tar.gz 1011064 BLAKE2B 73c33ce38ba9417452024f66c9dff82e72aff24b42a78faa8d2457c33310e4550b54ca848856cd55ce7606a79192b9989b2fc622670434a10b7ec0002bd9e2e0 SHA512 4b46d64b61ea3b06dc2a1589855f5d6f87f2cc5a0bf482bda7843cfcd7731eaf85f8a1e8dc96856a479a576811fd1c3115ccb6526df1d797b268469b32f23a2f

games-util/ProtonUp-Qt/ProtonUp-Qt-2.13.0.ebuild

@@ -0,0 +1,65 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{12..13} )
+
+inherit desktop distutils-r1 xdg
+
+DESCRIPTION="Install and manage GE-Proton, Luxtorpeda & more for Steam Lutris and Heroic."
+HOMEPAGE="https://davidotek.github.io/protonup-qt/"
+
+SRC_URI="
+	https://github.com/DavidoTek/ProtonUp-Qt/archive/refs/tags/v${PV}.tar.gz
+		-> ${P}.tar.gz
+"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/pyaml-6.0[${PYTHON_USEDEP}]
+	>=dev-python/pyside-6.3.0[dbus,gui,uitools,widgets,${PYTHON_USEDEP}]
+	>=dev-python/pyxdg-0.27[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.27.0[${PYTHON_USEDEP}]
+	>=dev-python/steam-1.6.1[${PYTHON_USEDEP}]
+	>=dev-python/vdf-4.0[${PYTHON_USEDEP}]
+	>=dev-python/zstandard-0.19.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/responses[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_DESELECT=(
+	# pytest-responses is not packaged
+	tests/test_util.py::test_is_online
+	tests/test_util.py::test_is_online_errors
+)
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# execute entry point instead
+	sed -i "/^Exec=/s/net.davidotek.pupgui2/${PN,,}/" share/applications/net.davidotek.pupgui2.desktop || die
+	# pytest-responses is not packaged (and not useful for us anyway)
+	sed -i -e "/^import pytest_responses/d" tests/test_util.py || die
+	distutils-r1_src_prepare
+}
+
+src_install() {
+	distutils-r1_src_install
+	domenu share/applications/net.davidotek.pupgui2.desktop
+	for size in 64 128 256; do
+		doicon -s ${size} share/icons/hicolor/${size}x${size}/apps/net.davidotek.pupgui2.png
+	done
+}
+
+src_test() {
+	local -x QT_QPA_PLATFORM=offscreen
+	distutils-r1_src_test
+}

games-util/ProtonUp-Qt/ProtonUp-Qt-9999.ebuild

@@ -16,24 +16,33 @@ LICENSE="GPL-3"
 SLOT="0"
 
 RDEPEND="
-	dev-python/pyaml[${PYTHON_USEDEP}]
+	>=dev-python/pyaml-6.0[${PYTHON_USEDEP}]
-	dev-python/pyside[dbus,gui,uitools,widgets,${PYTHON_USEDEP}]
+	>=dev-python/pyside-6.3.0[dbus,gui,uitools,widgets,${PYTHON_USEDEP}]
-	dev-python/pyxdg[${PYTHON_USEDEP}]
+	>=dev-python/pyxdg-0.27[${PYTHON_USEDEP}]
-	dev-python/requests[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.27.0[${PYTHON_USEDEP}]
-	dev-python/steam[${PYTHON_USEDEP}]
+	>=dev-python/steam-1.6.1[${PYTHON_USEDEP}]
-	dev-python/vdf[${PYTHON_USEDEP}]
+	>=dev-python/vdf-4.0[${PYTHON_USEDEP}]
-	dev-python/zstandard[${PYTHON_USEDEP}]
+	>=dev-python/zstandard-0.19.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/responses[${PYTHON_USEDEP}]
+	)
 "
 
-PATCHES=(
+EPYTEST_DESELECT=(
-	"${FILESDIR}/${PN}-2.11.1-add-entrypoint.patch"
+	# pytest-responses is not packaged
+	tests/test_util.py::test_is_online
+	tests/test_util.py::test_is_online_errors
 )
 
 distutils_enable_tests pytest
 
 src_prepare() {
 	# execute entry point instead
-	sed -i "/^Exec=/s/net.davidotek.pupgui2/${PN}/" share/applications/net.davidotek.pupgui2.desktop || die
+	sed -i "/^Exec=/s/net.davidotek.pupgui2/${PN,,}/" share/applications/net.davidotek.pupgui2.desktop || die
+	# pytest-responses is not packaged (and not useful for us anyway)
+	sed -i -e "/^import pytest_responses/d" tests/test_util.py || die
 	distutils-r1_src_prepare
 }