diff --git a/dev-python/opentelemetry-exporter-otlp-proto-grpc/Manifest b/dev-python/opentelemetry-exporter-otlp-proto-grpc/Manifest
new file mode 100644
index 0000000000..664dd8eb51
--- /dev/null
+++ b/dev-python/opentelemetry-exporter-otlp-proto-grpc/Manifest
@@ -0,0 +1 @@
+DIST opentelemetry-python-1.40.0.gh.tar.gz 1380277 BLAKE2B a52ce43e047347d55ce3ba54c2db4fa883f7e543eac9cfe4e3aa92f03db3a0a2fa943235e9f1fe61b5b7bfe377f7c3a661822405c357e2b31885ca7f20c636d6 SHA512 3c5ff022f0374cd28248a8d08d3e909945833db06afaced75d3bafe1420b3e2686e8a5aa14c60bd01380dd0a22c3c08c92caed2671925f3cea4aa40f383c83c1
diff --git a/dev-python/opentelemetry-exporter-otlp-proto-grpc/metadata.xml b/dev-python/opentelemetry-exporter-otlp-proto-grpc/metadata.xml
new file mode 100644
index 0000000000..e4443370ae
--- /dev/null
+++ b/dev-python/opentelemetry-exporter-otlp-proto-grpc/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>falbrechtskirchinger@gmail.com</email>
+		<name>Florian Albrechtskirchinger</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="pypi">opentelemetry-exporter-otlp-proto-grpc</remote-id>
+		<remote-id type="github">open-telemetry/opentelemetry-python</remote-id>
+	</upstream>
+</pkgmetadata>
diff --git a/dev-python/opentelemetry-exporter-otlp-proto-grpc/opentelemetry-exporter-otlp-proto-grpc-1.40.0.ebuild b/dev-python/opentelemetry-exporter-otlp-proto-grpc/opentelemetry-exporter-otlp-proto-grpc-1.40.0.ebuild
new file mode 100644
index 0000000000..746ce28c97
--- /dev/null
+++ b/dev-python/opentelemetry-exporter-otlp-proto-grpc/opentelemetry-exporter-otlp-proto-grpc-1.40.0.ebuild
@@ -0,0 +1,56 @@
+# Copyright 2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{11..14} )
+
+inherit distutils-r1
+
+MY_P="opentelemetry-python-${PV}"
+DESCRIPTION="OpenTelemetry Collector Protobuf over gRPC Exporter"
+HOMEPAGE="
+	https://opentelemetry.io/
+	https://pypi.org/project/opentelemetry-exporter-otlp-proto-grpc/
+	https://github.com/open-telemetry/opentelemetry-python/
+"
+SRC_URI="
+	https://github.com/open-telemetry/opentelemetry-python/archive/refs/tags/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S="${WORKDIR}/${MY_P}/exporter/${PN}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/googleapis-common-protos-1.57[${PYTHON_USEDEP}]
+	>=dev-python/grpcio-1.75.1[${PYTHON_USEDEP}]
+	~dev-python/opentelemetry-api-${PV}[${PYTHON_USEDEP}]
+	~dev-python/opentelemetry-exporter-otlp-proto-common-${PV}[${PYTHON_USEDEP}]
+	~dev-python/opentelemetry-proto-${PV}[${PYTHON_USEDEP}]
+	>=dev-python/typing-extensions-4.6.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		~dev-python/opentelemetry-sdk-${PV}[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+python_test() {
+	cp -a "${BUILD_DIR}"/{install,test} || die
+	local -x PATH=${BUILD_DIR}/test/usr/bin:${PATH}
+
+	for dep in tests/opentelemetry-test-utils; do
+		pushd "${WORKDIR}/${MY_P}/${dep}" >/dev/null || die
+		distutils_pep517_install "${BUILD_DIR}"/test
+		popd >/dev/null || die
+	done
+
+	epytest tests
+}