dev-python/zope-testrunner: new package, add 5.6

Signed-off-by: Julien Roy <julien@jroy.ca>

dev-python/zope-testrunner/Manifest

@@ -0,0 +1 @@
+DIST zope-testrunner-5.6.gh.tar.gz 134768 BLAKE2B 2b7a653bc3a35886044b9843f5e5dce4f94da7de79ec6a3be19841943370c48882809460ae40f188ed909d0c57366784cbcf3f6e075bd10f7dec3c98d910d72d SHA512 bce65e5cd64f7ddbe2b1aad359d084e1b7175ce7186b08ab9b24e3cc745c0b118ce69e4f09e86bf27a420823192b60f9d1a21ac02dd66abfbdd5c10986302b61

dev-python/zope-testrunner/metadata.xml

@@ -0,0 +1,19 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<name>Julien Roy</name>
+		<email>julien@jroy.ca</email>
+	</maintainer>
+	<upstream>
+		<maintainer>
+			<name>Zope Foundation and Contributors</name>
+			<email>zope-dev@zope.org</email>
+		</maintainer>
+		<changelog>https://github.com/zopefoundation/zope.testrunner/blob/master/CHANGES.rst</changelog>
+		<doc>https://zopetestrunner.readthedocs.io/</doc>
+		<bugs-to>https://github.com/zopefoundation/zope.testrunner/issues</bugs-to>
+		<remote-id type="github">zopefoundation/zope.testrunner</remote-id>
+		<remote-id type="pypi">zope.testrunner</remote-id>
+	</upstream>
+</pkgmetadata>

dev-python/zope-testrunner/zope-testrunner-5.6.ebuild

@@ -0,0 +1,59 @@
+# Copyright 2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="This package provides a flexible test runner with layer support."
+HOMEPAGE="https://github.com/zopefoundation/zope.testrunner"
+SRC_URI="https://github.com/zopefoundation/zope.testrunner/archive/${PV}.tar.gz -> ${P}.gh.tar.gz"
+S="${WORKDIR}/${PN/-/\.}-${PV}"
+
+LICENSE="ZPL"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/zope-interface[${PYTHON_USEDEP}]
+	dev-python/zope-exceptions[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinxcontrib-programoutput[${PYTHON_USEDEP}] )
+	test? ( dev-python/zope-testing[${PYTHON_USEDEP}] )
+"
+DEPEND="${RDEPEND}"
+
+distutils_enable_sphinx docs
+distutils_enable_tests unittest
+
+src_unpack() {
+	default
+	# Remove test that causes QA warnings
+	rm "${S}/src/zope/testrunner/tests/testrunner-ex/sample2/badsyntax.py" || die
+}
+
+src_prepare() {
+	# strip rdep specific to namespaces
+	sed -i -e "/'setuptools'/d" setup.py || die
+	distutils-r1_src_prepare
+}
+
+python_compile() {
+	distutils-r1_python_compile
+	find "${BUILD_DIR}" -name '*.pth' -delete || die
+}
+
+python_test() {
+	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+	distutils_write_namespace zope
+	eunittest
+}
+
+python_install() {
+	# Do not install unit tests
+	rm -r "${BUILD_DIR}/install$(python_get_sitedir)/zope/testrunner/tests" || die
+	distutils-r1_python_install
+}