mirrors/guru
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/guru.git synced 2026-04-07 03:10:15 -04:00
Code Issues Packages Projects Releases Wiki Activity

dev-embedded/qdl: several improvements

Browse Source 
* add SLOT to dependencies
* wire up tests
* fix displayed version
* add manpages
* remove LICENSE from doc dir
* sync -9999, which is tag v2.4 at the moment

Acked-by: Quincy Fleming <quincyf467@protonmail.com>
Part-of: https://github.com/gentoo/guru/pull/415
Closes: https://github.com/gentoo/guru/pull/415
Signed-off-by: Lucio Sauer <watermanpaint@posteo.net>
This commit is contained in:
Lucio Sauer
2026-01-07 22:26:22 +01:00
parent ee35df7341
commit 8bcc26e21a
3 changed files with 67 additions and 43 deletions
Download Patch File Download Diff File Expand all files Collapse all files

46
dev-embedded/qdl/qdl-2.4-r1.ebuild Normal file
View File

@@ -0,0 +1,46 @@
# Copyright 2023-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit toolchain-funcs
DESCRIPTION="Tool to communicate with Qualcomm System On a Chip bootroms"
HOMEPAGE="https://github.com/linux-msm/qdl"
SRC_URI="https://github.com/linux-msm/qdl/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64"
DEPEND="
dev-libs/libusb:1
dev-libs/libxml2:=
"
RDEPEND="${DEPEND}"
BDEPEND="
sys-apps/help2man
virtual/pkgconfig
"
src_compile() {
# $(VERSION) needs to be consistent in all make invocations
export VERSION="${PV}"
local PKG_CONFIG="$(tc-getPKG_CONFIG)"
emake CC="$(tc-getCC)" \
CFLAGS="${CFLAGS} $(${PKG_CONFIG} --cflags libxml-2.0 libusb-1.0 || die)" \
LDFLAGS="${LDFLAGS} $(${PKG_CONFIG} --libs libxml-2.0 libusb-1.0 || die)"
emake manpages
}
src_test() {
emake tests
}
src_install() {
emake prefix="${EPREFIX}/usr" DESTDIR="${D}" install
doman *.1
einstalldocs
}

34
dev-embedded/qdl/qdl-2.4.ebuild
View File

@@ -1,34 +0,0 @@
# Copyright 2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit toolchain-funcs
DESCRIPTION="Tool to communicate with Qualcomm System On a Chip bootroms"
HOMEPAGE="https://github.com/linux-msm/qdl"
SRC_URI="https://github.com/linux-msm/qdl/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64"
DEPEND="
dev-libs/libusb
dev-libs/libxml2
"
RDEPEND="${DEPEND}"
BDEPEND="virtual/pkgconfig"
src_compile() {
PKG_CONFIG=$(tc-getPKG_CONFIG)
emake CC=$(tc-getCC) \
"CFLAGS=${CFLAGS} `${PKG_CONFIG} --cflags libxml-2.0 libusb-1.0`" \
"LDFLAGS=${LDFLAGS} `${PKG_CONFIG} --libs libxml-2.0 libusb-1.0`"
}
src_install() {
emake prefix="${EPREFIX}/usr" DESTDIR="${D}" install
dodoc {README.md,LICENSE}
}

30
dev-embedded/qdl/qdl-9999.ebuild
View File

@@ -1,4 +1,4 @@
# Copyright 2023 Gentoo Authors
# Copyright 2023-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
@@ -13,21 +13,33 @@ LICENSE="BSD"
SLOT="0"
DEPEND="
dev-libs/libusb
dev-libs/libxml2
dev-libs/libusb:1
dev-libs/libxml2:=
"
RDEPEND="${DEPEND}"
BDEPEND="virtual/pkgconfig"
BDEPEND="
sys-apps/help2man
virtual/pkgconfig
"
src_compile() {
PKG_CONFIG=$(tc-getPKG_CONFIG)
emake CC=$(tc-getCC) \
"CFLAGS=${CFLAGS} `${PKG_CONFIG} --cflags libxml-2.0 libusb-1.0`" \
"LDFLAGS=${LDFLAGS} `${PKG_CONFIG} --libs libxml-2.0 libusb-1.0`"
# $(VERSION) needs to be consistent in all make invocations
export VERSION="${PV}"
local PKG_CONFIG="$(tc-getPKG_CONFIG)"
emake CC="$(tc-getCC)" \
CFLAGS="${CFLAGS} $(${PKG_CONFIG} --cflags libxml-2.0 libusb-1.0 || die)" \
LDFLAGS="${LDFLAGS} $(${PKG_CONFIG} --libs libxml-2.0 libusb-1.0 || die)"
emake manpages
}
src_test() {
emake tests
}
src_install() {
emake prefix="${EPREFIX}/usr" DESTDIR="${D}" install
dodoc {README.md,LICENSE}
doman *.1
einstalldocs
}