From 89df56447f018180d6a18ee3e5ceaf6c8368b7fb Mon Sep 17 00:00:00 2001
From: "Anna (cybertailor) Vyalkova" <cyber+gentoo@sysrq.in>
Date: Wed, 1 Mar 2023 05:54:41 +0500
Subject: [PATCH] dev-python/fontParts: enable py3.11

Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>
---
 .../fontParts/fontParts-0.10.6-r1.ebuild      | 42 +++++++++++++++++++
 dev-python/fontParts/fontParts-0.10.6.ebuild  | 37 ----------------
 2 files changed, 42 insertions(+), 37 deletions(-)
 create mode 100644 dev-python/fontParts/fontParts-0.10.6-r1.ebuild
 delete mode 100644 dev-python/fontParts/fontParts-0.10.6.ebuild

diff --git a/dev-python/fontParts/fontParts-0.10.6-r1.ebuild b/dev-python/fontParts/fontParts-0.10.6-r1.ebuild
new file mode 100644
index 0000000000..27aa9cef5f
--- /dev/null
+++ b/dev-python/fontParts/fontParts-0.10.6-r1.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+DISTUTILS_USE_PEP517=setuptools
+inherit distutils-r1
+
+DESCRIPTION="An API for interacting with the parts of fonts"
+HOMEPAGE="
+	https://pypi.org/project/fontParts/
+	https://github.com/robotools/fontParts
+"
+SRC_URI="https://github.com/robotools/${PN}/archive/refs/tags/${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+KEYWORDS="~amd64 ~x86"
+LICENSE="MIT"
+SLOT="0"
+
+RDEPEND="
+	>=dev-python/booleanOperations-0.9.0[${PYTHON_USEDEP}]
+	>=dev-python/defcon-0.6.0[${PYTHON_USEDEP}]
+	>=dev-python/fontMath-0.4.8[${PYTHON_USEDEP}]
+	>=dev-python/fontPens-0.1.0[${PYTHON_USEDEP}]
+	>=dev-python/fonttools-3.32.0[${PYTHON_USEDEP}]
+	>=dev-python/fs-2.2.0[${PYTHON_USEDEP}]
+	>=dev-python/lxml-4.9.2[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep \
+		'>=dev-python/unicodedata2-14.0.0[${PYTHON_USEDEP}]' \
+		python3_{9..10})
+"
+BDEPEND="dev-python/setuptools-scm[${PYTHON_USEDEP}]"
+
+distutils_enable_tests pytest
+
+distutils_enable_sphinx documentation/source
+
+src_configure() {
+	export SETUPTOOLS_SCM_PRETEND_VERSION="${PV}"
+	distutils-r1_src_configure
+}
diff --git a/dev-python/fontParts/fontParts-0.10.6.ebuild b/dev-python/fontParts/fontParts-0.10.6.ebuild
deleted file mode 100644
index c18e5a80d3..0000000000
--- a/dev-python/fontParts/fontParts-0.10.6.ebuild
+++ /dev/null
@@ -1,37 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{9..10} )
-
-inherit distutils-r1
-
-DESCRIPTION="An API for interacting with the parts of fonts"
-HOMEPAGE="https://github.com/robotools/fontParts"
-SRC_URI="https://github.com/robotools/fontParts/archive/refs/tags/${PV}.tar.gz -> ${P}.gh.tar.gz"
-
-KEYWORDS="~amd64 ~x86"
-LICENSE="MIT"
-SLOT="0"
-IUSE="test"
-
-RDEPEND="
-	${PYTHON_DEPS}
-	>=dev-python/booleanOperations-0.9.0[${PYTHON_USEDEP}]
-	>=dev-python/defcon-0.6.0[${PYTHON_USEDEP}]
-	>=dev-python/fontMath-0.4.8[${PYTHON_USEDEP}]
-	>=dev-python/fonttools-3.32.0[${PYTHON_USEDEP}]
-"
-DEPEND="${RDEPEND}"
-BDEPEND="test? ( dev-python/fontPens[${PYTHON_USEDEP}] )"
-
-RESTRICT="!test? ( test )"
-
-pkg_setup() {
-	export SETUPTOOLS_SCM_PRETEND_VERSION="${PV%_*}"
-}
-
-python_test() {
-	"${EPYTHON}" Lib/fontParts/fontshell/test.py -v || die "Tests failed with ${EPYTHON}"
-}