dev-scheme/akku: new package; add version 1.1.0

Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Maciej Barć <xgqt@riseup.net>

dev-scheme/akku/Manifest

@@ -0,0 +1 @@
+DIST akku-v1.1.0.tar.gz 492996 BLAKE2B 7e3d549ed7f7fc0b6e84a41ff03d66398d2a464d6aa65dc92780a2b657d4476fef592543fba0fefe0da8ee429d97d4dcc0cf13ecd53c7be425b3f292b7b1c93d SHA512 e728bd80aaa21ca896e054e71a17ee519608b7c436f9613c688dba666f0120562174b7dca3156299528c1063a74e8faa8b8a77d1b7166d7506dec6b51d555825

dev-scheme/akku/akku-1.1.0.ebuild

@@ -0,0 +1,51 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="Language package manager for Scheme"
+HOMEPAGE="https://akkuscm.org/"
+
+if [[ "${PV}" == *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gitlab.com/akkuscm/${PN}.git"
+else
+	SRC_URI="https://gitlab.com/akkuscm/${PN}/-/archive/v${PV}/${PN}-v${PV}.tar.gz"
+	KEYWORDS="~amd64"
+	S="${WORKDIR}/${PN}-v${PV}"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+RESTRICT="strip"
+
+RDEPEND="
+	>=dev-scheme/guile-2.0.11:=
+	net-misc/curl[ssl]
+"
+DEPEND="${RDEPEND}"
+
+# Guile generates ELF files without use of C or machine code
+# It's a portage's false positive. bug #677600
+QA_PREBUILT='*[.]go'
+
+src_prepare() {
+	default
+
+	# http://debbugs.gnu.org/cgi/bugreport.cgi?bug=38112
+	find "${S}" -name "*.scm" -exec touch {} + || die
+
+	eautoreconf
+}
+
+src_configure() {
+	econf --prefix=/usr
+}
+
+src_compile() {
+	touch bootstrap.db || die
+
+	emake
+}

dev-scheme/akku/metadata.xml

@@ -0,0 +1,21 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+
+<pkgmetadata>
+  <maintainer type="person">
+    <email>xgqt@riseup.net</email>
+    <name>Maciej Barć</name>
+  </maintainer>
+  <longdescription lang="en">
+    Akku.scm is a language package manager for Scheme.
+    It grabs hold of code and vigorously shakes it until it behaves properly.
+    - No complicated setup to point out where libraries are; Akku finds them!
+    - Separately declare dependencies and locked versions for your project.
+    - Convert R7RS libraries for use with Chez Scheme and other R6RS Scheme implementations.
+    - Numerous R6RS packages, as well as R7RS libraries mirrored from Snow.
+  </longdescription>
+  <upstream>
+    <bugs-to>https://gitlab.com/akkuscm/akku/-/issues</bugs-to>
+    <remote-id type="gitlab">akkuscm/akku</remote-id>
+  </upstream>
+</pkgmetadata>