dev-util/blueprint-compiler: Add 0.4.0

Signed-off-by: Yuan Liao <liaoyuan@gmail.com>

dev-util/blueprint-compiler/Manifest

@@ -1 +1,2 @@
 DIST blueprint-compiler-v0.2.0.tar.bz2 45480 BLAKE2B 64c477070ea684002dc1e38eac8d22633ae7b46efb9887733118838c04d2c4e386d3825b3e07dcba1adada83afad439025d082d3bd74d2d737c1f5552085a716 SHA512 dfb16354a13a18c0e6db52dc0b88ab7339fbf3eb56541d0a273551c009c7f05c651d41814397986ef2cebdefb6d4e57d0eb3690dd2a7a9eebfb0cfb23e96e3e6
+DIST blueprint-compiler-v0.4.0.tar.bz2 50396 BLAKE2B eb51af35030fbaa583b809de0449e7e54143a7b5e582b9be24a0345ca704fb1b1d2778d96ebfb02cc66e4c4acdc97a0356e03624f33be1ea28316ed815c0e334 SHA512 9eb3b17e8b44ecd400c1ec683bf1edee54877a0f16e545ba2f9f9cb683163983fd096ff9403ab36658f92678036f4b6b43e1343cf2bc4793332ef4b2972408ac

dev-util/blueprint-compiler/blueprint-compiler-0.4.0.ebuild

@@ -0,0 +1,92 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit meson python-r1
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gitlab.gnome.org/jwestman/blueprint-compiler.git"
+else
+	SRC_URI="https://gitlab.gnome.org/jwestman/blueprint-compiler/-/archive/v${PV}/blueprint-compiler-v${PV}.tar.bz2"
+	S="${WORKDIR}/${PN}-v${PV}"
+	KEYWORDS="~amd64"
+fi
+
+DESCRIPTION="Compiler for Blueprint, a markup language for GTK user interfaces"
+HOMEPAGE="https://jwestman.pages.gitlab.gnome.org/blueprint-compiler/"
+
+LICENSE="LGPL-3+"
+SLOT="0"
+
+IUSE="doc test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	${PYTHON_DEPS}
+	doc? (
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/furo[${PYTHON_USEDEP}]
+	)
+"
+
+DEPEND="
+	test? (
+		gui-libs/gtk:4[introspection]
+	)
+"
+
+RDEPEND="
+	${PYTHON_DEPS}
+"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use doc docs)
+	)
+	python_foreach_impl meson_src_configure
+}
+
+src_compile() {
+	python_foreach_impl meson_src_compile
+}
+
+src_test() {
+	python_foreach_impl meson_src_test
+}
+
+src_install() {
+	my_src_install() {
+		local exe="${ED}/usr/bin/${PN}"
+
+		# Meson installs a Python script at ${ED}/usr/bin/${PN}; on
+		# Gentoo, the script should go into ${ED}/usr/lib/python-exec,
+		# and ${ED}/usr/bin/${PN} should be a symbolic link to
+		# ${ED}/usr/lib/python-exec/python-exec2.
+		#
+		# When multiple PYTHON_TARGETS are enabled, then after the
+		# package has been installed for one Python implementation,
+		# Meson will follow the ${ED}/usr/bin/${PN} symbolic link and
+		# install the script at ${ED}/usr/lib/python-exec/python-exec2
+		# for the remaining implementations, leading to file collision.
+		if [[ -L "${exe}" ]]; then
+			rm -v "${exe}" || die "Failed to remove symbolic link ${exe}"
+		fi
+
+		meson_src_install
+		python_doscript "${exe}"
+		python_optimize
+
+		# Install Sphinx-generated documentation only once
+		# since the documentation is supposed to be identical
+		# between different Python implementations
+		use doc && HTML_DOCS=( "${BUILD_DIR}/docs"/* )
+	}
+
+	python_foreach_impl my_src_install
+	einstalldocs
+}