dev-python/geopy: version bump 2.0.0, add py3.9

Package-Manager: Portage-3.0.12, Repoman-3.0.2
Signed-off-by: Andrew Ammerlaan <andrewammerlaan@riseup.net>

dev-python/geopy/geopy-2.0.0.ebuild

@@ -0,0 +1,55 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+PYTHON_COMPAT=( python3_{7,8,9} )
+
+inherit distutils-r1
+
+DESCRIPTION="A Geocoding Toolbox for Python"
+HOMEPAGE="
+	https://geopy.readthedocs.io
+	https://github.com/geopy/geopy
+	https://pypi.org/project/geopy
+"
+SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	<sci-geosciences/geographiclib-2[python,${PYTHON_USEDEP}]
+	>=sci-geosciences/geographiclib-1.49[python,${PYTHON_USEDEP}]
+"
+BDEPEND="test? (
+	dev-python/pytest-aiohttp[${PYTHON_USEDEP}]
+	dev-python/mock[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+)"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs \
+				">=dev-python/sphinx_rtd_theme-0.4.0" \
+				dev-python/readme_renderer
+
+python_prepare_all() {
+	# [Errno -3] Temporary failure in name resolution
+	rm test/test_adapters.py || die
+	rm test/geocoders/algolia.py || die
+	rm test/geocoders/arcgis.py || die
+	rm test/geocoders/banfrance.py || die
+	rm test/geocoders/databc.py || die
+	rm test/geocoders/geocodefarm.py || die
+	rm test/geocoders/geonames.py || die
+	rm test/geocoders/nominatim.py || die
+	rm test/geocoders/photon.py || die
+
+	# depend on the above and now fail to import
+	rm test/geocoders/openmapquest.py || die
+	rm test/geocoders/pickpoint.py || die
+
+	distutils-r1_python_prepare_all
+}