app-crypt/firefox-decrypt: new package, add 1.1.1

Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>

app-crypt/firefox-decrypt/Manifest

@@ -0,0 +1 @@
+DIST firefox-decrypt-1.1.1.tar.gz 95537 BLAKE2B 778cef025b9a84e751bd1331b89d51a98b674aef82d768f789c8ae5ebbaf1c528a192e8d20111259e2eb33ef07de25da5e0126629ac2b65c2d5455610d7f4e7d SHA512 2604cd27d88520c8397524b2b6d12e02a2f9fe14211754f3111aec5d9f112c528b749f6c2a032c1a01fc5038edede01c45d54a4ba0ed2ee40fd411085c3e0052

app-crypt/firefox-decrypt/firefox-decrypt-1.1.1.ebuild

@@ -0,0 +1,41 @@
+# Copyright 2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{11..12} )
+PYTHON_REQ_USE="sqlite"
+DISTUTILS_USE_PEP517=setuptools
+DISTUTILS_SINGLE_IMPL=1
+DISTUTILS_IN_SOURCE_BUILD=
+inherit distutils-r1
+
+DESCRIPTION="Tool to extract passwords from Mozilla (Firefox, Thunderbird, etc.) profiles"
+HOMEPAGE="https://github.com/Unode/firefox_decrypt"
+SRC_URI="https://github.com/unode/${PN/-/_}/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN/-/_}-${PV}"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="dev-libs/nss"
+BDEPEND="
+	$(python_gen_cond_dep 'dev-python/setuptools-scm[${PYTHON_USEDEP}]')
+"
+
+distutils_enable_tests setup.py
+
+src_prepare() {
+	rm tests/version.t || die
+	distutils-r1_src_prepare
+}
+
+python_prepare() {
+	python_fix_shebang "${S}"/tests
+}
+
+python_test() {
+	cd "${S}"/tests || die
+	${EPYTHON} run_all -v || die
+}

app-crypt/firefox-decrypt/metadata.xml

@@ -0,0 +1,14 @@
+<?xml version='1.0' encoding='UTF-8'?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>cyber+gentoo@sysrq.in</email>
+		<name>Anna</name>
+	</maintainer>
+	<upstream>
+		<maintainer>
+			<name>Renato Alves</name>
+		</maintainer>
+		<remote-id type="github">Unode/firefox_decrypt</remote-id>
+	</upstream>
+</pkgmetadata>