dev-python/oscrypto: fix tests

Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>

dev-python/oscrypto/Manifest

@@ -1 +1 @@
-DIST oscrypto-1.3.0.tar.gz 313874 BLAKE2B 6dd3331978d0ca8e63a136988d55bd6e1314078256f6c5141f26d49382e8908b58974c8f8d281a98a7e5efff2e477488baf7a37e3ea4a17bf887c92f9b1d9985 SHA512 b5baf72e1a09615b267be4d1c4baf2375bb939b5bd3d717ca9ca70776541f590a8608bef95991967e23f3794e6220709ed2fe5acdedfe9bfce1921c879a74bec
+DIST oscrypto-1.3.0.gh.tar.gz 313874 BLAKE2B 6dd3331978d0ca8e63a136988d55bd6e1314078256f6c5141f26d49382e8908b58974c8f8d281a98a7e5efff2e477488baf7a37e3ea4a17bf887c92f9b1d9985 SHA512 b5baf72e1a09615b267be4d1c4baf2375bb939b5bd3d717ca9ca70776541f590a8608bef95991967e23f3794e6220709ed2fe5acdedfe9bfce1921c879a74bec

dev-python/oscrypto/oscrypto-1.3.0-r1.ebuild

@@ -0,0 +1,42 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} pypy3 )
+DISTUTILS_USE_PEP517=setuptools
+inherit edo distutils-r1 optfeature
+
+DESCRIPTION="TLS sockets, key generation, encryption, decryption, signing, verification"
+HOMEPAGE="
+	https://pypi.org/project/oscrypto/
+	https://github.com/wbond/oscrypto
+"
+SRC_URI="https://github.com/wbond/${PN}/archive/${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-libs/openssl
+	>=dev-python/asn1crypto-1.5.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		virtual/python-cffi[${PYTHON_USEDEP}]
+	)
+"
+
+DOCS=( docs {changelog,readme}.md )
+
+distutils_enable_tests unittest
+
+python_test() {
+	local -x OSCRYPTO_SKIP_INTERNET_TESTS="true"
+	edo ${EPYTHON} -m tests
+}
+
+pkg_postinst() {
+	optfeature "faster FFI" virtual/python-cffi
+}

dev-python/oscrypto/oscrypto-1.3.0.ebuild

@@ -1,35 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{8..11} pypy3 )
-
-inherit distutils-r1
-
-DESCRIPTION="TLS sockets, key generation, encryption, decryption, signing, verification"
-HOMEPAGE="
-	https://github.com/wbond/oscrypto
-	https://pypi.org/project/oscrypto/
-"
-SRC_URI="https://github.com/wbond/oscrypto/archive/${PV}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="test"
-
-RDEPEND=">=dev-python/asn1crypto-1.5.1[${PYTHON_USEDEP}]"
-DEPEND="${RDEPEND}"
-
-RESTRICT="test"
-PROPERTIES="test_network"
-
-python_test() {
-	"${EPYTHON}" run.py tests || die
-}
-
-python_install_all() {
-	distutils-r1_python_install_all
-	dodoc -r docs/*
-}