gui-apps/swaync: add 0.12.1

Signed-off-by: Anthony Ruhier <aruhier@mailbox.org>

gui-apps/swaync/Manifest

@@ -1 +1,2 @@
 DIST swaync-0.11.0.tar.gz 1717108 BLAKE2B 2adc0f4090cef20d2bd5180f96418914caf6b33ec2221de804a5b68e02ca5327d99752620afb653786ee95312f7608161aad5b7dfff68c9f51dc5ee5ccfec5e3 SHA512 1fcad5e1c5cfd09d0c8e71fe5b5e6717daed245c127ad405bb0e95722f3a346d78f23d97e0f78a0a35357f1e32551e5149ffc2963959ae6364d709545df15f07
+DIST swaync-0.12.1.tar.gz 1727353 BLAKE2B 2cfb4f98c5493d9f77f9eac9abcff2d10e3bf79601b96220a19ced270caabfcbc183ce8587067367117c223db7d977c483c4f0c6646fb5a0771a8a00e474abd8 SHA512 0b17ce988128aaccf615d123f17b1d53ca448a6a2bec15e0350f16b3a29696a9d210587bef2f29d30d80365c39bc6bcc74d9d49fb0e6f677cfc66f4074016808

gui-apps/swaync/swaync-0.12.1.ebuild

@@ -0,0 +1,65 @@
+# Copyright 2022-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{12..13} )
+inherit meson vala gnome2-utils python-any-r1
+VALA_USE_DEPEND="vapigen"
+
+MY_PN="SwayNotificationCenter"
+DESCRIPTION="A simple notification daemon with a GTK gui for notifications and control center"
+HOMEPAGE="https://github.com/ErikReider/SwayNotificationCenter"
+SRC_URI="https://github.com/ErikReider/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="pulseaudio"
+
+DEPEND="
+	dev-lang/sassc
+	dev-libs/glib:2
+	dev-libs/gobject-introspection
+	dev-libs/granite:=
+	dev-libs/json-glib
+	dev-libs/libgee:0.8=
+	dev-libs/wayland
+	gui-libs/gtk4-layer-shell[introspection,vala]
+	gui-libs/gtk:4
+	gui-libs/libadwaita
+	pulseaudio? ( media-libs/libpulse )
+	sys-apps/dbus
+	x11-libs/gdk-pixbuf:2
+"
+RDEPEND="
+	${DEPEND}
+	x11-libs/cairo
+	x11-libs/pango
+"
+
+BDEPEND="
+	${PYTHON_DEPS}
+	$(vala_depend)
+	app-text/scdoc
+	dev-util/blueprint-compiler
+"
+
+src_configure() {
+	local emesonargs=($(meson_use pulseaudio pulse-audio))
+	meson_src_configure
+}
+
+src_prepare() {
+	default
+	vala_setup
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	gnome2_schemas_update
+}