From 7c5d172a9e341dfe391da20b909ce50cecd692d0 Mon Sep 17 00:00:00 2001
From: Yuan Liao <liaoyuan@gmail.com>
Date: Sat, 11 Jun 2022 08:08:34 -0700
Subject: [PATCH] dev-util/blueprint-compiler: Add 0.2.0

Signed-off-by: Yuan Liao <liaoyuan@gmail.com>
---
 dev-util/blueprint-compiler/Manifest          |  1 +
 .../blueprint-compiler-0.2.0.ebuild           | 61 +++++++++++++++++++
 2 files changed, 62 insertions(+)
 create mode 100644 dev-util/blueprint-compiler/blueprint-compiler-0.2.0.ebuild

diff --git a/dev-util/blueprint-compiler/Manifest b/dev-util/blueprint-compiler/Manifest
index b133c1653b..7535fa13b7 100644
--- a/dev-util/blueprint-compiler/Manifest
+++ b/dev-util/blueprint-compiler/Manifest
@@ -1 +1,2 @@
 DIST blueprint-compiler-0.1.0_pre20220419.tar.gz 53439 BLAKE2B 1683356aa10ffdc6b1f6b5d072a301bbc2cdde2eb986f22aa83c269af1fa8cc100910ca790b2b94056db926221b42d2f8309019ee10442374d7e915ab5ec2ed3 SHA512 9017667728723d0e9358ffe9e868f743093cadc7434275c5805f406da72d5cd7afcb5af394c5610446ab6cebdddafc52f65723e16950b3aae47c8739b77e3ef1
+DIST blueprint-compiler-v0.2.0.tar.bz2 45480 BLAKE2B 64c477070ea684002dc1e38eac8d22633ae7b46efb9887733118838c04d2c4e386d3825b3e07dcba1adada83afad439025d082d3bd74d2d737c1f5552085a716 SHA512 dfb16354a13a18c0e6db52dc0b88ab7339fbf3eb56541d0a273551c009c7f05c651d41814397986ef2cebdefb6d4e57d0eb3690dd2a7a9eebfb0cfb23e96e3e6
diff --git a/dev-util/blueprint-compiler/blueprint-compiler-0.2.0.ebuild b/dev-util/blueprint-compiler/blueprint-compiler-0.2.0.ebuild
new file mode 100644
index 0000000000..0fc9a3e312
--- /dev/null
+++ b/dev-util/blueprint-compiler/blueprint-compiler-0.2.0.ebuild
@@ -0,0 +1,61 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..10} )
+
+inherit meson python-single-r1
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gitlab.gnome.org/jwestman/blueprint-compiler.git"
+else
+	SRC_URI="https://gitlab.gnome.org/jwestman/blueprint-compiler/-/archive/v${PV}/blueprint-compiler-v${PV}.tar.bz2"
+	S="${WORKDIR}/${PN}-v${PV}"
+	KEYWORDS="~amd64"
+fi
+
+DESCRIPTION="Compiler for Blueprint, a markup language for GTK user interfaces"
+HOMEPAGE="https://jwestman.pages.gitlab.gnome.org/blueprint-compiler/"
+
+LICENSE="LGPL-3+"
+SLOT="0"
+
+IUSE="doc test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	${PYTHON_DEPS}
+	doc? (
+		$(python_gen_cond_dep '
+			dev-python/sphinx[${PYTHON_USEDEP}]
+			dev-python/furo[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+DEPEND="
+	test? (
+		gui-libs/gtk:4[introspection]
+	)
+"
+
+RDEPEND="
+	${PYTHON_DEPS}
+"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use doc docs)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	use doc && HTML_DOCS=( "${BUILD_DIR}/docs"/* )
+	meson_src_install
+	python_optimize "${D}/usr/share/${PN}"
+	python_fix_shebang "${D}/usr/bin/${PN}"
+}