dev-libs/open62541: add 1.3.8

Signed-off-by: Kurt Kanzenbach <kurt@kmk-computers.de>

dev-libs/open62541/Manifest

@@ -1 +1,2 @@
 DIST open62541-1.3.7.tar.gz 3871057 BLAKE2B 68bd5f2090dc94cbfa7e0b299e744371559fb580fcc32f6bb02ab3d3aadb90454e75a9478f1997a630d04ce14696289b79e7aab375c5e55ac82d3f2c3f97e0fb SHA512 c0598642eaddf24313b22f01b95646aed508aaf1d39f8f6cbcc9ffa679fab73c9407e880480a39e50deb16fa5f36d769183d8fe4589f7ac54d97142d2a27a84b
+DIST open62541-1.3.8.tar.gz 3874185 BLAKE2B bce0d1c3dadff3cb34baceb6142f7b40a032fe602e8d8a6e35f24ea1d20bcfd8de655092eb77ac07bfcd98331c9de58ebe684929c82c35d499cb9615278a5a7f SHA512 48ae61fd096c3a45f57ecc70bec9bb4223d046eed017532937c99883e4e92f79d7425b4db02c1a7e451764b787313efd76b2ae3cd3011d575154199d5350a790

dev-libs/open62541/open62541-1.3.8.ebuild

@@ -0,0 +1,89 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit cmake python-single-r1
+
+DESCRIPTION="Open source C implementation of OPC UA"
+HOMEPAGE="https://www.open62541.org/"
+SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc encryption examples mbedtls pubsub openssl tools"
+# Requires network access
+RESTRICT="test"
+
+REQUIRED_USE="
+	${PYTHON_REQUIRED_USE}
+	encryption? ( || ( mbedtls openssl ) )
+"
+
+BDEPEND="
+	${PYTHON_DEPS}
+	virtual/pkgconfig
+	doc? (
+		media-gfx/graphviz
+		$(python_gen_cond_dep '
+			dev-python/sphinx[${PYTHON_USEDEP}]
+			dev-python/sphinx-rtd-theme[${PYTHON_USEDEP}]
+		')
+	)
+"
+DEPEND="
+	mbedtls? ( net-libs/mbedtls:= )
+	openssl? ( dev-libs/openssl:0= )
+"
+RDEPEND="
+	${PYTHON_DEPS}
+	${DEPEND}
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.3.5-disable-xdp.patch"
+)
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_SHARED_LIBS=ON
+		-DOPEN62541_VERSION=v${PV}
+		-DUA_BUILD_EXAMPLES=OFF
+		-DUA_BUILD_TOOLS=$(usex tools)
+		-DUA_BUILD_UNIT_TESTS=OFF
+		-DUA_ENABLE_PUBSUB=$(usex pubsub)
+		-DUA_ENABLE_PUBSUB_ETH_UADP=$(usex pubsub)
+		-DUA_FORCE_WERROR=OFF
+	)
+
+	if use encryption; then
+		use mbedtls && mycmakeargs+=(-DUA_ENABLE_ENCRYPTION=MBEDTLS)
+		use openssl && mycmakeargs+=(-DUA_ENABLE_ENCRYPTION=OPENSSL)
+	fi
+
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+	use doc && cmake_build doc
+}
+
+src_install() {
+	use doc && local HTML_DOCS=( "${WORKDIR}"/${P}_build/doc/. )
+	cmake_src_install
+
+	if use examples; then
+		docompress -x /usr/share/doc/${PF}/examples
+		dodoc -r examples/
+	fi
+
+	python_fix_shebang "${ED}"
+}
+
+src_test() {
+	cmake_src_test -j1
+}