app-misc/fastfetch: add 1.3.0

Signed-off-by: Viorel Munteanu <ceamac.paragon@gmail.com>

app-misc/fastfetch/Manifest

@@ -1 +1,2 @@
 DIST fastfetch-1.2.3.tar.gz 328561 BLAKE2B d52ba5a41eda9cd12cca01ae0387854586f7e3d5594155a20c22fa311b919ade7f71b089c39eb8044ebfb38b486c5d259a1b9f6a671ac7c60e2b36ca5f9d21c5 SHA512 239f695239a181ffb3b1b8d836d67e2876d2e7bfa9d75f3dc74c615e5497e510d1610347b72e3a8a1c31295fd48f6cad4f108592e2cdc9261f209318ca74b154
+DIST fastfetch-1.3.0.tar.gz 335013 BLAKE2B 7834a19225d1abfb9f81981b9fc445c9d989db050d89289a4e8a9c9fa620991d4a6f9c4aa5cb5eb861fdc8d73d98ec9bd1b8ec009544f78b983291fabe6e07e8 SHA512 46b835ac4b767703c32398fa97b64b64fde6874b92f34747ca675377796cdfa551c0a2697d6435dfd3818ded12520ef3c7cd6c79a9ade30e8a62c7d44ccd1882

app-misc/fastfetch/fastfetch-1.3.0.ebuild

@@ -0,0 +1,61 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="Like neofetch but faster"
+HOMEPAGE="https://github.com/LinusDierheimer/fastfetch"
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/LinusDierheimer/fastfetch.git"
+else
+	SRC_URI="https://github.com/LinusDierheimer/fastfetch/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="X gnome pci vulkan wayland xcb xfce xrandr"
+
+# note - qa-vdb will always report errors because fastfetch loads the libs dynamically
+RDEPEND="
+	media-gfx/imagemagick:=
+	sys-libs/zlib
+	X? ( x11-libs/libX11 )
+	gnome? (
+		dev-libs/glib
+		gnome-base/dconf
+	)
+	pci? ( sys-apps/pciutils )
+	vulkan? ( media-libs/vulkan-loader )
+	wayland? ( dev-libs/wayland )
+	xcb? ( x11-libs/libxcb )
+	xfce? ( xfce-base/xfconf )
+	xrandr? ( x11-libs/libXrandr )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+REQUIRED_USE="xrandr? ( X )"
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_RPM=no
+		-DENABLE_VULKAN=$(usex vulkan)
+		-DENABLE_WAYLAND=$(usex wayland)
+		-DENABLE_XCB_RANDR=$(usex xcb)
+		-DENABLE_XCB=$(usex xcb)
+		-DENABLE_XRANDR=$(usex xrandr)
+		-DENABLE_X11=$(usex X)
+		-DENABLE_GIO=$(usex gnome)
+		-DENABLE_DCONF=$(usex gnome)
+		-DENABLE_XFCONF=$(usex xfce)
+		-DENABLE_IMAGEMAGICK7=$(has_version '>=media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+		-DENABLE_IMAGEMAGICK6=$(has_version '<media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+		-DENABLE_ZLIB=yes
+	)
+
+	cmake_src_configure
+}

app-misc/fastfetch/fastfetch-9999.ebuild

@@ -20,6 +20,8 @@ IUSE="X gnome pci vulkan wayland xcb xfce xrandr"
 
 # note - qa-vdb will always report errors because fastfetch loads the libs dynamically
 RDEPEND="
+	media-gfx/imagemagick:=
+	sys-libs/zlib
 	X? ( x11-libs/libX11 )
 	gnome? (
 		dev-libs/glib
@@ -49,6 +51,9 @@ src_configure() {
 		-DENABLE_GIO=$(usex gnome)
 		-DENABLE_DCONF=$(usex gnome)
 		-DENABLE_XFCONF=$(usex xfce)
+		-DENABLE_IMAGEMAGICK7=$(has_version '>=media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+		-DENABLE_IMAGEMAGICK6=$(has_version '<media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+		-DENABLE_ZLIB=yes
 	)
 
 	cmake_src_configure