diff --git a/dev-util/rtc-testbench/Manifest b/dev-util/rtc-testbench/Manifest
index 9a3c768485..bc9dfb7583 100644
--- a/dev-util/rtc-testbench/Manifest
+++ b/dev-util/rtc-testbench/Manifest
@@ -1 +1,2 @@
 DIST rtc-testbench-5.3.tar.gz 2107611 BLAKE2B 9297ea4ffd77cc4d94f5b7ba873f392c4b89ee95970c205e2888a0a4f20ce20215d6db4370ee36304d4026d8acf9101b482ecd3dc3f7806f6ff364be356f4a86 SHA512 32bb6277f330d3e50ca7028043b3bbef9559074b8e436ba294e3ae9673fbd7373706759bdbca82636cd74ffef687a91d04f9fdb5520ac3cff6ef0267bc80fc2b
+DIST rtc-testbench-5.4.tar.gz 2132516 BLAKE2B 43d8c8f14c957da28ad51fb06c07c1dc6f6ca777c3f0b347dacdb0dd41864d53efb60e5d1f945b8204bb4a92a2856a4aa3b451de47d6033783ff43205ff4b29d SHA512 95bfa2b83f0b7e36f48bef69cd78a8994734109802a60dd9b2585634d4158034160ce312cfdf280c59b7fba3038457259be094d9b5b4b39123be3e5806a2b9fa
diff --git a/dev-util/rtc-testbench/rtc-testbench-5.4.ebuild b/dev-util/rtc-testbench/rtc-testbench-5.4.ebuild
new file mode 100644
index 0000000000..b5dc54d905
--- /dev/null
+++ b/dev-util/rtc-testbench/rtc-testbench-5.4.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LLVM_COMPAT=( {15..20} )
+PYTHON_COMPAT=( python3_{12..13} )
+
+inherit cmake python-single-r1 llvm-r2
+
+DESCRIPTION="RTC Testbench is a set of tools for validating Ethernet networks"
+HOMEPAGE="https://github.com/Linutronix/RTC-Testbench"
+SRC_URI="https://github.com/Linutronix/RTC-Testbench/archive/refs/tags/v${PV}.tar.gz -> ${PN}-${PV}.tar.gz"
+S="${WORKDIR}/RTC-Testbench-${PV}"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc mqtt"
+
+# Generated eBPF files
+QA_PREBUILT="usr/lib*/rtc-testbench/ebpf/*.o"
+
+REQUIRED_USE="
+	${PYTHON_REQUIRED_USE}
+"
+
+BDEPEND="
+	${PYTHON_DEPS}
+	virtual/pkgconfig
+	doc? (
+		media-gfx/graphviz
+		$(python_gen_cond_dep '
+			dev-python/sphinx[${PYTHON_USEDEP}]
+			dev-python/sphinx-rtd-theme[${PYTHON_USEDEP}]
+		')
+	)
+	$(llvm_gen_dep '
+		llvm-core/clang:${LLVM_SLOT}=[llvm_targets_BPF(-)]
+	')
+"
+DEPEND="
+	mqtt? ( app-misc/mosquitto )
+	dev-libs/libyaml
+	dev-libs/libbpf:=
+	dev-libs/openssl:=
+	net-libs/xdp-tools
+"
+RDEPEND="
+	${PYTHON_DEPS}
+	${DEPEND}
+"
+
+pkg_setup() {
+	llvm-r2_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_MQTT=$(usex mqtt)
+	)
+
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+	use doc && make -C "${S}/Documentation" html
+}
+
+src_install() {
+	cmake_src_install
+	use doc && HTML_DOCS=( "${S}/Documentation/_build/html" )
+}