diff --git a/media-gfx/grawji/Manifest b/media-gfx/grawji/Manifest
new file mode 100644
index 0000000000..ebd60e18cb
--- /dev/null
+++ b/media-gfx/grawji/Manifest
@@ -0,0 +1 @@
+DIST grawji-0.2.0.gh.tar.gz 1448770 BLAKE2B 19a01e2f64525df749b2e379880f99d6cba0b6a804ec25a0a5b866cb183dbe7a6bca6f3f9557e8d12ef375186cb56860ab47a5617af867fefc29c40e40cb3f5e SHA512 6f3caafeca19e25bd20161556e77f8c92f4d6fe33e68554eb1e28c76f9bc5ef6809a0cae93fda372547d9841c216342f463c151826c1779b2fedcc5d42f8208d
diff --git a/media-gfx/grawji/grawji-0.2.0.ebuild b/media-gfx/grawji/grawji-0.2.0.ebuild
new file mode 100644
index 0000000000..f64f420cef
--- /dev/null
+++ b/media-gfx/grawji/grawji-0.2.0.ebuild
@@ -0,0 +1,44 @@
+# Copyright 2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{12..15} )
+
+inherit distutils-r1 virtualx
+
+DESCRIPTION="GTK4 frontend for rawji, interactive Fujifilm RAF conversion"
+HOMEPAGE="https://github.com/p5k369/grawji"
+SRC_URI="https://github.com/p5k369/grawji/archive/refs/tags/v${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-python/pygobject:3[${PYTHON_USEDEP}]
+	dev-python/rawji[${PYTHON_USEDEP}]
+	gui-libs/gtk:4[introspection]
+	gui-libs/libadwaita:1[introspection]
+	media-libs/gexiv2[introspection]
+"
+
+EPYTEST_PLUGINS=()
+
+EPYTEST_IGNORE=(
+	# the pin is replaced by dev-python/rawji here.
+	tests/test_rawji_pin.py
+)
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	# rawji is provided by dev-python/rawji
+	sed -i 's|"rawji @ git+[^"]*"|"rawji"|' pyproject.toml || die
+	default
+}
+
+src_test() {
+	virtx distutils-r1_src_test
+}
diff --git a/media-gfx/grawji/metadata.xml b/media-gfx/grawji/metadata.xml
new file mode 100644
index 0000000000..ae4239889d
--- /dev/null
+++ b/media-gfx/grawji/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>patrick@p5k.org</email>
+		<name>Patrick Zwerschke</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">p5k369/grawji</remote-id>
+	</upstream>
+</pkgmetadata>