diff --git a/app-misc/fastfetch/Manifest b/app-misc/fastfetch/Manifest
index 572de412c3..f400db4f70 100644
--- a/app-misc/fastfetch/Manifest
+++ b/app-misc/fastfetch/Manifest
@@ -1,2 +1,3 @@
 DIST fastfetch-1.6.5.tar.gz 350944 BLAKE2B 51ef09e23656af1368be49b88f83a80d7028184f2dedeec7a392dfd4c578cf9d50ca29d40bae7b6856e733dad4da30525c33aae5ec5e6ab9d7eaeb9d43f72697 SHA512 795d0a23ebe09162f22db985c67e9ffbc6772765ee8b052a6fa78fd61ec12651e45932ab17247876545065c40f57040d90f7117cb991c78f84271141c7bff3e5
 DIST fastfetch-1.7.0.tar.gz 423699 BLAKE2B cc48b6b0cc1b04049d864d5d2a15cff8cca2e8e7cec9929d919e5fc5149fed55edaba520227c53ae3b0ab4633a65ce5cd590f75948256c228dd69fd9dae3c57b SHA512 ac5fde8a7920e6381c3636b1e39a4cf3abe665eb2a3a895d4ee72d269defc49c61ef796708fe8f60a6e48e02265bd4ab79eea9bcf0528f8cba46ec7a8bd3947e
+DIST fastfetch-1.7.2.tar.gz 426097 BLAKE2B 5f9714b735605d4cc4cf8179f048c4cff24db0010f91e080f5e6c0f41329cbc155cdb883775ccb98bda77bfd4efb1f2b79f0adad4a2694d338b0027a31f170b1 SHA512 9f3051d8b9bc22ef93a2e6993c553c5a18d475c8cbb16a63087706aa823a0a4806c49aabb3cdbf5f240f9c9325ea5cb7db2498adcc87c9e44b77d26f6c28a39f
diff --git a/app-misc/fastfetch/fastfetch-1.7.2.ebuild b/app-misc/fastfetch/fastfetch-1.7.2.ebuild
new file mode 100644
index 0000000000..7536a14ff9
--- /dev/null
+++ b/app-misc/fastfetch/fastfetch-1.7.2.ebuild
@@ -0,0 +1,85 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="Fast system information tool"
+HOMEPAGE="https://github.com/LinusDierheimer/fastfetch"
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/LinusDierheimer/fastfetch.git"
+else
+	SRC_URI="https://github.com/LinusDierheimer/fastfetch/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="X chafa dbus gnome imagemagick opencl opengl osmesa pci sqlite vulkan wayland xcb xfce xrandr"
+
+# note - qa-vdb will always report errors because fastfetch loads the libs dynamically
+RDEPEND="
+	sys-libs/zlib
+	X? ( x11-libs/libX11 )
+	chafa? ( media-gfx/chafa )
+	dbus? ( sys-apps/dbus )
+	gnome? (
+		dev-libs/glib
+		gnome-base/dconf
+	)
+	imagemagick? ( media-gfx/imagemagick:= )
+	opencl? ( virtual/opencl )
+	opengl? ( media-libs/libglvnd[X] )
+	osmesa? ( media-libs/mesa[osmesa] )
+	pci? ( sys-apps/pciutils )
+	sqlite? ( dev-db/sqlite:3 )
+	vulkan? ( media-libs/vulkan-loader )
+	wayland? ( dev-libs/wayland )
+	xcb? ( x11-libs/libxcb )
+	xfce? ( xfce-base/xfconf )
+	xrandr? ( x11-libs/libXrandr )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+REQUIRED_USE="
+	xrandr? ( X )
+	chafa? ( imagemagick )
+"
+
+src_configure() {
+	local fastfetch_enable_imagemagick7=no
+	local fastfetch_enable_imagemagick6=no
+	if use imagemagick; then
+		fastfetch_enable_imagemagick7=$(has_version '>=media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+		fastfetch_enable_imagemagick6=$(has_version '<media-gfx/imagemagick-7.0.0' && echo yes || echo no)
+	fi
+
+	local mycmakeargs=(
+		-DENABLE_RPM=no
+		-DENABLE_LIBPCI=$(usex pci)
+		-DENABLE_VULKAN=$(usex vulkan)
+		-DENABLE_WAYLAND=$(usex wayland)
+		-DENABLE_XCB_RANDR=$(usex xcb)
+		-DENABLE_XCB=$(usex xcb)
+		-DENABLE_XRANDR=$(usex xrandr)
+		-DENABLE_X11=$(usex X)
+		-DENABLE_GIO=$(usex gnome)
+		-DENABLE_DCONF=$(usex gnome)
+		-DENABLE_XFCONF=$(usex xfce)
+		-DENABLE_IMAGEMAGICK7=${fastfetch_enable_imagemagick7}
+		-DENABLE_IMAGEMAGICK6=${fastfetch_enable_imagemagick6}
+		-DENABLE_ZLIB=yes
+		-DENABLE_CHAFA=$(usex chafa)
+		-DENABLE_SQLITE3=$(usex sqlite)
+		-DENABLE_EGL=$(usex opengl)
+		-DENABLE_GLX=$(usex opengl)
+		-DENABLE_OSMESA=$(usex osmesa)
+		-DENABLE_OPENCL=$(usex opencl)
+		-DENABLE_DBUS=$(usex dbus)
+	)
+
+	cmake_src_configure
+}
diff --git a/app-misc/fastfetch/fastfetch-9999.ebuild b/app-misc/fastfetch/fastfetch-9999.ebuild
index d739843126..4413ff7318 100644
--- a/app-misc/fastfetch/fastfetch-9999.ebuild
+++ b/app-misc/fastfetch/fastfetch-9999.ebuild
@@ -5,7 +5,7 @@ EAPI=8
 
 inherit cmake
 
-DESCRIPTION="Like neofetch but faster"
+DESCRIPTION="Fast system information tool"
 HOMEPAGE="https://github.com/LinusDierheimer/fastfetch"
 if [[ ${PV} == *9999 ]]; then
 	inherit git-r3
diff --git a/app-misc/fastfetch/metadata.xml b/app-misc/fastfetch/metadata.xml
index f23f66aa32..736c75c137 100644
--- a/app-misc/fastfetch/metadata.xml
+++ b/app-misc/fastfetch/metadata.xml
@@ -17,4 +17,9 @@
 	<flag name="xfce">Enables support for XFCE config</flag>
 	<flag name="xrandr">Enables support for Xrandr</flag>
 </use>
+<longdescription>
+fastfetch is a neofetch-like tool for fetching system information and displaying them in a pretty way.
+
+It is written in c to achieve much better performance.
+</longdescription>
 </pkgmetadata>