From 7498b284ea6cda3d46010b84ec3027e8177abe31 Mon Sep 17 00:00:00 2001
From: Paul Zander <negril.nx+gentoo@gmail.com>
Date: Wed, 17 Jun 2026 13:58:48 +0200
Subject: [PATCH] x11-drivers/evdi: add 1.14.16

Signed-off-by: Paul Zander <negril.nx+gentoo@gmail.com>
---
 x11-drivers/evdi/Manifest            |  1 +
 x11-drivers/evdi/evdi-1.14.16.ebuild | 98 ++++++++++++++++++++++++++++
 2 files changed, 99 insertions(+)
 create mode 100644 x11-drivers/evdi/evdi-1.14.16.ebuild

diff --git a/x11-drivers/evdi/Manifest b/x11-drivers/evdi/Manifest
index 0247c469f8..c916270bd3 100644
--- a/x11-drivers/evdi/Manifest
+++ b/x11-drivers/evdi/Manifest
@@ -2,3 +2,4 @@ DIST evdi-1.14.12.tar.gz 97369 BLAKE2B 096220d88306c17e29f5d65593e3c291d577fd031
 DIST evdi-1.14.13.tar.gz 97875 BLAKE2B e80eacd284355d96d28b99e928d22b6bb36ff3d49963dd4736ce56ff1e97d949fbb3b04bde6d3e0c5750fbab54c4985c85c74da183a385768821343f3aa7ee60 SHA512 13990b72114703a29fac61e4f8164f372f85d8ef3d32a0c5326121bb0e51ab4cbc8860c03807ac4704b9ddcf1bb381bd05783de288537e9c8eb61a18bbc29b2e
 DIST evdi-1.14.14.tar.gz 98722 BLAKE2B 9b14e9a01378617b581d82bbe8ce07a5b61932f9a27b5e8e92cb824b9dfd20625bc9cf95ffbd966033f052b2e89633126daa7fd85cf04dc408faa24f4948f660 SHA512 9acdb41f2dbc1bc8222490e10caa903beb12fc8d3532b45b8ec86a59fcde89aa0e2eb779b503aadcffc4b1e6c22b82f4e6bea56a100a653beca60f0d37e6392e
 DIST evdi-1.14.15.tar.gz 96427 BLAKE2B a788c070833b855b7cc2356d0f0b4d1dd1029c60ffc4c34192bea28a0f05b308f9a681878ef088e9ecb4264921f3b037d2d8220bf4a5cc49ca609e5c5ab63b8e SHA512 0306819e8a0a02de7f90128049c21fd2cc51c3e5fab7c7491de1f7b2cd9435acc09f6c2c543a547bb68e880881cdbefc7a415ee6fd2204ba580795e7e1a49e56
+DIST evdi-1.14.16.tar.gz 96489 BLAKE2B b0eae2f6a9a1e835888fea8608c0b7f970f652ffe3b534209535c4ec30a22337f8b72a214b0a94b3cd73d47eb0c26a9e41fbdf3353b96630be1b21328425dd84 SHA512 6bab7c6cababdf9105156547396d9aeefaf631108fa2c76c3bb098cf9e215a6f7eeb4081592a9ec1810e7556fc9fa5b66dad4c75d503d539e1744780a7215477
diff --git a/x11-drivers/evdi/evdi-1.14.16.ebuild b/x11-drivers/evdi/evdi-1.14.16.ebuild
new file mode 100644
index 0000000000..7700fd887b
--- /dev/null
+++ b/x11-drivers/evdi/evdi-1.14.16.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{12..14} )
+inherit linux-mod-r1 python-single-r1 flag-o-matic
+
+DESCRIPTION="Extensible Virtual Display Interface"
+HOMEPAGE="https://github.com/DisplayLink/evdi"
+
+if [[ "${PV}" = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/DisplayLink/evdi.git"
+else
+	if [[ "${PV}" = *_p* ]] ; then
+		EVDI_COMMIT="5d708d117baab842d6960f0ec61808a1541bda57"
+		SRC_URI="https://github.com/DisplayLink/evdi/archive/${EVDI_COMMIT}.tar.gz -> ${P}.tar.gz"
+		S="${WORKDIR}/${PN}-${EVDI_COMMIT}"
+	else
+		SRC_URI="https://github.com/DisplayLink/evdi/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+	fi
+
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+fi
+
+LICENSE="GPL-2 LGPL-2.1+"
+SLOT="0/$(ver_cut 1)"
+
+IUSE="python test"
+
+RDEPEND="${PYTHON_DEPS}
+	python? (
+		$(python_gen_cond_dep '
+			dev-python/pybind11[${PYTHON_USEDEP}]
+			test? (
+				dev-python/pytest-mock[${PYTHON_USEDEP}]
+			)
+		')
+	)
+"
+
+DEPEND="${RDEPEND}
+	x11-libs/libdrm
+	sys-kernel/linux-headers
+"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RESTRICT="!test? ( test )"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-1.14.4-format-truncation.patch"
+)
+
+pkg_setup() {
+	# module/Kconfig
+	local CONFIG_CHECK="~FB_VIRTUAL ~I2C ~DRM ~USB_SUPPORT ~USB_ARCH_HAS_HCD MODULES"
+
+	linux-mod-r1_pkg_setup
+
+	use python && python-single-r1_pkg_setup
+}
+
+src_compile() {
+	# TODO ERROR: modpost: missing MODULE_LICENSE() in evdi.o
+	filter-lto
+
+	local modlist=(
+		"evdi=video:module"
+	)
+	local modargs=(
+		CONFIG_DRM_EVDI="m" # https://github.com/DisplayLink/evdi/issues/476
+		KVER="${KV_FULL}"
+		KDIR="${KV_OUT_DIR}"
+	)
+	linux-mod-r1_src_compile
+
+	emake -C library
+
+	use python && emake -C pyevdi
+}
+
+src_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+
+	use python && emake -C pyevdi tests
+}
+
+src_install() {
+	linux-mod-r1_src_install
+
+	local -x DESTDIR="${ED}" PREFIX="${EPREFIX}"
+
+	LIBDIR="/usr/$(get_libdir)" emake -C library install
+
+	use python && emake -C pyevdi install
+}